oracle:如何用sql生成日歷

BI分析中，經常需要將事實表與時間維度表關聯起來，按年/月/日來逐層展示，常用的做法是創建一張日歷表，結構類似如下：

create table T_BAS_CALENDAR
(
  d_year  NUMBER(4) not null,
  d_month NUMBER(2) not null,
  d_day   NUMBER(2) not null
);
comment on table T_BAS_CALENDAR
  is '日歷表';
comment on column T_BAS_CALENDAR.d_year
  is '年';
comment on column T_BAS_CALENDAR.d_month
  is '月';
comment on column T_BAS_CALENDAR.d_day
  is '日';
alter table T_BAS_CALENDAR
  add constraint PK_BAS_CALENDAR primary key (D_YEAR, D_MONTH, D_DAY);

但是如何向這張表批量插入日歷數據，方法就很多了，下面是僅用SQL語言生成日歷的參考方法：

create or replace procedure P_IMPORT_CALENDAR(p_year_start number,
                                              p_year_end   number) is
  cmonth    integer;
  cyear     integer;
  cday      integer;
  day_first integer;
  day_last  integer;
begin
  --生成從p_year_start到p_year_end的所有日歷 created by [e-mail] 2015-04-27
  
  --firstly,delete history records
  delete from T_BAS_CALENDAR where d_year between p_year_start and p_year_end;
  for cyear in p_year_start .. p_year_end loop
    for cmonth in 1 .. 12 loop
      --get first-day of Month
      select to_number(cyear || lpad(cmonth, 2, '0') || '01', '99999999')
        into day_first
        from dual;
      --last-day of Month
      select to_number(to_char(add_months(to_date(day_first, 'yyyyMMdd'), 1) - 1,
                               'yyyyMMdd'),
                       '99999999')
        into day_last
        from dual;
      for cday in day_first .. day_last loop   
        --insert to table  
        INSERT INTO T_BAS_CALENDAR
          (D_YEAR, D_MONTH, D_DAY)
        VALUES
          (CYEAR, CMONTH, SUBSTR(cday, 7));
      end loop;
    end loop;
  end loop;
  commit;
end P_IMPORT_CALENDAR;