QunInfo群數據庫的還原與優化

一、 背景

　　這個數據庫的數據文件mdf大概有8.5G左右，當還原數據庫之后感覺可以做很多性能方面上的調優，合並數據后mdf數據文件大概有6.2G左右，行壓縮后mdf數據文件大概有4.8G左右，頁壓縮后mdf數據文件大概有4.5G左右，這里處於技術研究的目的，講講研究的成果分析，不用於商業目的；

 

二、 優化項

我們可以從下面3個不同的方面來優化這兩個數據庫：

（一）對表進行分區；

（二）使用行壓縮，壓縮行數據；

（三）重新設計表結構，優化表空間；

 

三、 附加數據庫

1．先把11個QunInfo（群信息）數據庫附加到數據庫，下面的導入SQL語句在原來的基礎上做了些修改：統一數據庫名，這樣做的好處就是后面做處理的時候方便按照順序執行數據庫；

--附加數據庫
EXEC sp_attach_db "QunInfo01", "D:\DBBackup\QunData\QunInfo1_Data.MDF"
EXEC sp_attach_db "QunInfo02", "D:\DBBackup\QunData\QunInfo2_Data.MDF"
EXEC sp_attach_db "QunInfo03", "D:\DBBackup\QunData\QunInfo3_Data.MDF"
EXEC sp_attach_db "QunInfo04", "D:\DBBackup\QunData\QunInfo4_Data.MDF"
EXEC sp_attach_db "QunInfo05", "D:\DBBackup\QunData\QunInfo5_Data.MDF"
EXEC sp_attach_db "QunInfo06", "D:\DBBackup\QunData\QunInfo6_Data.MDF"
EXEC sp_attach_db "QunInfo07", "D:\DBBackup\QunData\QunInfo7_Data.MDF"
EXEC sp_attach_db "QunInfo08", "D:\DBBackup\QunData\QunInfo8_Data.MDF"
EXEC sp_attach_db "QunInfo09", "D:\DBBackup\QunData\QunInfo9_Data.MDF"
EXEC sp_attach_db "QunInfo10", "D:\DBBackup\QunData\QunInfo10_Data.MDF"
EXEC sp_attach_db "QunInfo11", 
"D:\DBBackup\QunData\QunInfo11_Data.MDF"

 

四、 合並數據庫

2．修改各個數據庫中表的名字：把QunList1統一修改為QunList01這樣格式的，這樣做的好處就是在合並數據的時候讀取到的數據庫的數據是按照順序插入到表中的，不會造成數據頁的拆分；

--格式化表名
USE QunInfo01
GO

exec sp_rename 'QunList1','QunList01'
exec sp_rename 'QunList2','QunList02'
exec sp_rename 'QunList3','QunList03'
exec sp_rename 'QunList4','QunList04'
exec sp_rename 'QunList5','QunList05'
exec sp_rename 'QunList6','QunList06'
exec sp_rename 'QunList7','QunList07'
exec sp_rename 'QunList8','QunList08'
exec sp_rename 'QunList9','QunList09'

 

3．創建一個名為QunInfo的數據庫，設置數據庫為簡單恢復模式；

 

4．在QunInfo數據庫中創建一個臨時表：tables，用來保存所有的數據庫與表的信息，提供數據庫合並用；

--創建臨時表
CREATE TABLE [QunInfo].[dbo].[tables](
    [db_name] [sysname] NULL,
    [table_name] [sysname] NULL,
    [status] [bit] default 0
) ON [PRIMARY]

--生成數據庫名稱與表名稱的對應列表
EXEC sp_MSForEachDB 'USE [?];
    --插入表信息
    INSERT INTO [QunInfo].[dbo].[tables]([table_name])
        SELECT name from [?].sys.tables where name like ''QunList%'' order by name
    --更新數據庫名稱
    UPDATE [QunInfo].[dbo].[tables] SET [db_name] = ''?'' WHERE [db_name]

 

五、 優化數據庫

5．經過評估，11個QunInfo數據庫的QunList表數據的總和大概有9千萬，QunList表中QunNum（群號）字段的最大值為100219998（可以通過QunInfo11數據庫的QunList110表查詢到：SELECT MAX(QunNum) FROM [QunInfo11].[dbo].[QunList110]），從業務的角度，可能需要查詢某群的信息，所以這里就以QunNum作為分區，每1千萬個群作為一個分區，這樣計算那就需要11個文件組，如果你希望和GroupData數據庫的Group表對齊的話，也可以按照5百萬個群作為一個分區；

 

6．下面是一個創建分區腳本的SQL腳本，執行下面的SQL會生成一個新的腳本，執行那個腳本就可以創建11個文件組、分區函數和分區方案；

--生成分區腳本
DECLARE @DataBaseName NVARCHAR(50)--數據庫名稱
DECLARE @TableName NVARCHAR(50)--表名稱
DECLARE @ColumnName NVARCHAR(50)--字段名稱
DECLARE @PartNumber INT--分區最大編號
DECLARE @PartNumberBegin INT--分區編號開始值
DECLARE @PartNumberBeginTemp INT--分區編號開始值臨時值
DECLARE @PartNumberStr NVARCHAR(50)--分區值字符串
DECLARE @Location NVARCHAR(50)--保存分區文件的路徑
DECLARE @Size NVARCHAR(50)--分區初始化大小
DECLARE @FileGrowth NVARCHAR(50)--分區文件增量
DECLARE @FunValue INT--分區分段值增量
DECLARE @FunValueBegin INT--分區分段值開始值
DECLARE @i INT--臨時變量
DECLARE @sql NVARCHAR(max)

--設置下面變量
SET @DataBaseName = 'QunInfo'
SET @TableName = 'QunList'
SET @ColumnName = 'QunNum'
SET @PartNumber = 11
SET @PartNumberBegin = 1
SET @Location = 'D:\DBBackup\FG_QunList\'
SET @Size = '1024MB'
SET @FileGrowth = '1024MB'
SET @FunValueBegin = 10000000
SET @FunValue = 10000000

SET @sql = 'USE ['+@DataBaseName +']
GO'
PRINT @sql + CHAR(13)

--1.創建文件組
SET @i = 1
SET @PartNumberBeginTemp = @PartNumberBegin
PRINT '--1.創建文件組'
WHILE @i <= @PartNumber
BEGIN
    SET @PartNumberStr =  RIGHT('0' + CONVERT(NVARCHAR,@PartNumberBeginTemp),2)
    SET @sql = 'ALTER DATABASE ['+@DataBaseName +']
ADD FILEGROUP [FG_'+@TableName+'_'+@ColumnName+'_'+@PartNumberStr+']'
    PRINT @sql + CHAR(13)
    SET @i=@i+1
    SET @PartNumberBeginTemp = @PartNumberBeginTemp+1
END

--2.創建文件
SET @i = 1
SET @PartNumberBeginTemp = @PartNumberBegin
PRINT CHAR(13)+'--2.創建文件'
WHILE @i <= @PartNumber
BEGIN
    SET @PartNumberStr =  RIGHT('0' + CONVERT(NVARCHAR,@PartNumberBeginTemp),2)
    SET @sql = 'ALTER DATABASE ['+@DataBaseName +']
ADD FILE
(NAME = N''FG_'+@TableName+'_'+@ColumnName+'_'+@PartNumberStr+'_data'',FILENAME = N'''+@Location+'FG_'+@TableName+'_'+@ColumnName+'_'+@PartNumberStr+'_data.ndf'',SIZE = '+@Size+', FILEGROWTH = '+@FileGrowth+' )
TO FILEGROUP [FG_'+@TableName+'_'+@ColumnName+'_'+@PartNumberStr+'];'
    PRINT @sql + CHAR(13)
    SET @i=@i+1
    SET @PartNumberBeginTemp = @PartNumberBeginTemp+1
END


--3.創建分區函數
PRINT CHAR(13)+'--3.創建分區函數'
DECLARE @FunValueStr NVARCHAR(MAX)
DECLARE @PNB INT
SET @i = 1
SET @PNB = 1
SET @FunValueStr = convert(NVARCHAR(50),@FunValueBegin) + ','
WHILE @i < @PartNumber-1
BEGIN
    SET @FunValueStr = @FunValueStr + convert(NVARCHAR(50),(@FunValueBegin+@PNB*@FunValue)) + ','
    SET @i=@i+1
    SET @PNB=@PNB+1
END
SET @FunValueStr = substring(@FunValueStr,1,len(@FunValueStr)-1)
SET @sql = 'CREATE PARTITION FUNCTION
[Fun_'+@TableName+'_'+@ColumnName+'](INT) AS
RANGE RIGHT
FOR VALUES('+@FunValueStr+')'
PRINT @sql + CHAR(13)


--4.創建分區方案
PRINT CHAR(13)+'--4.創建分區方案'
DECLARE @FileGroupStr NVARCHAR(MAX) 
SET @i = 1
SET @PartNumberBeginTemp = @PartNumberBegin
SET @FileGroupStr = ''
WHILE @i <= @PartNumber
BEGIN
    SET @PartNumberStr =  RIGHT('0' + CONVERT(NVARCHAR,@PartNumberBeginTemp),2)
    SET @FileGroupStr = @FileGroupStr + '[FG_'+@TableName+'_'+@ColumnName+'_'+@PartNumberStr+'],'
    SET @i=@i+1
    SET @PartNumberBeginTemp = @PartNumberBeginTemp+1
END
SET @FileGroupStr = substring(@FileGroupStr,1,len(@FileGroupStr)-1)
SET @sql = 'CREATE PARTITION SCHEME
[Sch_'+@TableName+'_'+@ColumnName+'] AS
PARTITION [Fun_'+@TableName+'_'+@ColumnName+']
TO('+@FileGroupStr+')'
PRINT @sql + CHAR(13)


--5.分區函數的記錄數
PRINT CHAR(13)+'--5.分區函數的記錄數'
SET @sql = 'SELECT $PARTITION.[Fun_'+@TableName+'_'+@ColumnName+']('+@ColumnName+') AS Partition_num,
  MIN('+@ColumnName+') AS Min_value,MAX('+@ColumnName+') AS Max_value,COUNT(1) AS Record_num
FROM dbo.['+@TableName+']
GROUP BY $PARTITION.[Fun_'+@TableName+'_'+@ColumnName+']('+@ColumnName+')
ORDER BY $PARTITION.[Fun_'+@TableName+'_'+@ColumnName+']('+@ColumnName+');'
PRINT @sql + CHAR(13)

 

7．下面重新對QunList表進行設計，涉及的內容如下：

1) 在QunInfo數據庫中創建分區表QunList，這里已經把原表的ID字段去掉了，這個字段並沒有太大的意義；

2) 以[QunNum]作為聚集索引，而且是唯一的，這個需要開啟IGNORE_DUP_KEY = ON選項，這樣才可以在批量插入的時候忽略重復值；

3) 對原表的[MastQQ]字段從int類型變成smallint ，[CreateDate]字段從varchar(10)類型變為date，數據類型修改是為了減少表占用的空間，

4) 使用剛剛創建好的分區方案，之后創建的索引進行索引對齊；

5) 對表使用行壓縮，減少數據庫占用空間；

6) 對表進行頁壓縮會更節省空間？

--創建優化后的QunList表
CREATE TABLE [dbo].[QunList](
    [QunNum] [int] NOT NULL,
    [MastQQ] [smallint] NULL,
    [CreateDate] [date] NULL,
    [Title] [varchar](22) NULL,
    [Class] [varchar](38) NULL,
    [QunText] [varchar](80) NULL,
 CONSTRAINT [PK_QunList2] PRIMARY KEY CLUSTERED 
(
    [QunNum] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = ON, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON, DATA_COMPRESSION = ROW) ON [Sch_QunList_QunNum]([QunNum])
) ON [Sch_QunList_QunNum]([QunNum])
GO

（Figure1：GroupData原表結構）

（Figure2：GroupData新表結構）

8．把11個數據庫都合並到新創建的QunInfo的QunList表中；

--合並數據
DECLARE @tablename sysname
DECLARE @dbname sysname
DECLARE @sql NVARCHAR(max)

--游標
DECLARE @itemCur CURSOR
SET @itemCur = CURSOR FOR 
    SELECT db_name,table_name from [QunInfo].[dbo].[tables]

OPEN @itemCur
FETCH NEXT FROM @itemCur INTO @dbname,@tablename
WHILE @@FETCH_STATUS=0

BEGIN
    
    SET @sql = '
    INSERT INTO [QunInfo].[dbo].[QunList]
           ([QunNum]
           ,[MastQQ]
           ,[CreateDate]
           ,[Title]
           ,[Class]
           ,[QunText])
    SELECT [QunNum]
      ,[MastQQ]
      ,[CreateDate]
      ,[Title]
      ,[Class]
      ,[QunText]
    FROM ['+@dbname+'].[dbo].['+@tablename+']'
  
    EXEC(@sql)
    
    UPDATE [QunInfo].[dbo].[tables] SET status = 1 WHERE db_name = @dbname AND table_name = @tablename
    
    --返回SQL
    PRINT(@sql)PRINT('GO')+CHAR(13)

    FETCH NEXT FROM @itemCur INTO @dbname,@tablename
END 

CLOSE @itemCur
DEALLOCATE @itemCur

（Figure3：QunList表分區記錄數）

（Figure4：QunList數據行壓縮前）

（Figure5：QunList數據行壓縮后）

我們使用頁壓縮修改表QunList，看看數據占用大小的情況：

--頁壓縮
ALTER TABLE [QunList]  
REBUILD WITH (DATA_COMPRESSION = PAGE );

（Figure6：QunList數據頁壓縮后）