Arduino I2C + DS1307實時時鍾

主要特性

DS1307是Maxim的串行、I2C實時時鍾芯片。主要特性有：

• 工作電壓：主電源電壓4.5~5.5V，電池電壓2.0~3.5V
• 功耗：電池供電、備份模式時<500nA
• 接口：I2C，最大速率100kbps
• 可編程方波輸出
• 電源自動切換、失效檢測
• 內置56字節大小、支持電池備份的RAM
  
• 封裝：8-Pin SO/PDIP
  
  

管腳定義

• X1、X2: 接32.768kHz晶體，要求晶體負載電容12.5pF
• Vcc：主電源，范圍4.5~5.5V。當需要對DS1307讀寫時，需要接Vcc。
• VBAT：接電池，范圍2.0~3.5V。
• GND：地
• SDA、SCL：I2C接口數據線、時鍾線。
• SQW/OUT：方波輸出腳、通過寫寄存器來使能。
  
  

與Arduino的連接

采用I2C接口與Arduino連接。SQW/OUT腳亦為開漏（open-drain）設計，需要接上拉電阻。

DS1307的VCC腳接Arduino UNO的5V；GND腳接Arduino UNO的GND；SDA腳接Arduino UNO的A4(SDA)；SCL腳接Arduino UNO的A5(SCL)。

功能調試

1. 寫寄存器時，先寫入寄存器指針（Register pointer），之后依次寫入寄存器內容。每寫入一個字節，Register pointer都自動加一。

2. 讀寄存器時，也是先寫入Register pointer，之后發Sr（Repeated start），依次讀出寄存器內容。同樣的，每讀出一個字節，Register pinter都自動加一。

測試代碼

1. 首先設置DS1307時間。代碼中timeDec數組保存的是當前時間，根據實際調整。

/*
real time clock using DS1307
function: set the time
*/

#include <Wire.h>

#define ADDRESS_DS1307 0x68

byte timeDec[] = {15, 1, 15, 5, 19, 20, 0};
byte timeBcd[] = {0, 0, 0, 0, 0, 0, 0};
//time = {year, month, date, day, hours, minutes, seconds};

void setup()
{
    Wire.begin();
    Serial.begin(9600);

    //convert decimal to BCD code
    int i;
    for (i = 0; i < 7; i++)
    {
        timeBcd[i] = DecToBcd(timeDec[i]);
    }

    //set the time
    Wire.beginTransmission(ADDRESS_DS1307);
    Wire.write(0x00);
    for (i = 0; i < 7; i++)
    {
        Wire.write(timeBcd[6-i]);
    }
    Wire.endTransmission();

    Serial.println("Time has been set.");

}

void loop()
{
    delay(4000);
}

// Convert normal decimal numbers to binary coded decimal
byte DecToBcd(byte val)
{
    byte res;
    if ((val <= 99) && (val >= 0))
    {
        res = ((val/10)<<4) | (val%10);
    }
    else
    {
        res = 0;
        Serial.println("Error");
    }
    return res;
}
// Convert binary coded decimal to normal decimal numbers
byte BcdToDec(byte val)
{
    byte res;
    if (val <= 0x99)
    {
        res = (val >> 4)*10 + (val & 0x0F);
    }
    else
    {
        res = 0;
        Serial.println("Error");
    }
    return res;
}

2. 之后可以向DS1307獲取實時時間。

/*
real time clock using DS1307
function: read the time
*/

#include <Wire.h>

#define ADDRESS_DS1307 0x68

byte timeBcd[] = {0, 0, 0, 0, 0, 0, 0};
//time = {year, month, date, day, hours, minutes, seconds};

void setup()
{
    Wire.begin();
    Serial.begin(9600);
}

void loop()
{
    //read the time
    Wire.beginTransmission(ADDRESS_DS1307);
    Wire.write(0x00);
    Wire.endTransmission();
    Wire.requestFrom(ADDRESS_DS1307, 7);
    if (Wire.available() >= 7)
    {
        for (int i = 0; i < 7; i++)
        {
            timeBcd[6-i] = Wire.read();
        }
    }
    
    //print
    Serial.print("20"); Serial.print(timeBcd[0], HEX); Serial.print("/");
    Serial.print(timeBcd[1], HEX); Serial.print("/"); Serial.print(timeBcd[2], HEX);
    Serial.print(" "); Serial.print(BcdToDay(timeBcd[3])); Serial.print(" ");
    Serial.print(timeBcd[4], HEX); Serial.print(":");
    Serial.print(timeBcd[5], HEX); Serial.print(":");
    Serial.print(timeBcd[6], HEX); Serial.println();

    delay(1000);
}


// Convert binary coded decimal to day
String BcdToDay(byte val)
{
    String res;
    switch(val)
    {
        case 1: res = "Sunday"; break;
        case 2: res = "Monday"; break;
        case 3: res = "Tuesday"; break;
        case 4: res = "Wednesday"; break;
        case 5: res = "Thursday"; break;
        case 6: res = "Friday"; break;
        case 7: res = "Saturday"; break;
        default: res = "Error!";
    }
    return res;
}

程序運行后，通過串口打印當前時間如下圖。

3. 通過設置控制寄存器，可以設置SQW/OUT管腳輸出高電平、低電平或某個頻率的方波。方波支持的頻率有1Hz、4.096kHz、8.192kHz、32.768kHz。以下代碼設置的頻率為32.768kHz。

/*
real time clock using DS1307
function: output the square-wave
*/

#include <Wire.h>

#define ADDRESS_DS1307 0x68
#define CONTROL_REGISTER 0x07

void setup()
{
    Wire.begin();
    Serial.begin(9600);

    //set the time
    Wire.beginTransmission(ADDRESS_DS1307);
    Wire.write(CONTROL_REGISTER);
    Wire.write(0b00010011); //frequency = 32.768kHz
    Wire.endTransmission();

    Serial.println("Square-wave output is enabled.");
}

void loop()
{
    delay(4000);
}

與示波器測試的信號圖形相符。

參考資料

Maxim - DS1307 64x8、串行、I²C實時時鍾
Tutorial – Using DS1307 and DS3231 Real-time Clock Modules with Arduino
Digital Clock with Arduino and DS1307
Assemble an Adafruit DS1307 Real Time Clock Kit