知識點
值類型。
值類型是在棧中分配內存，在聲明時初始化才能使用，不能為null。
值類型超出作用范圍系統自動釋放內存。
主要由兩類組成：結構，枚舉（enum），結構分為以下幾類：
1、整型（Sbyte、Byte、Char、Short、Ushort、Int、Uint、Long、Ulong）
2、浮點型（Float、Double）
3、decimal
4、bool
5、用戶定義的結構（struct）
引用類型。
引用類型在堆中分配內存，初始化時默認為null。
引用類型是通過垃圾回收機制進行回收。
包括類、接口、委托、數組以及內置引用類型object與string。
概念
由於C#中所有的數據類型都是由基類System.Object繼承而來的，所以值類型和引用類型的值可以通過顯式
（或隱式）操作相互轉換，而這轉換過程也就是裝箱（boxing）和拆箱（unboxing）過程。
裝箱 是值類型到 object 類型或到此值類型所實現的任何接口類型的隱式轉換。對值類型裝箱會在堆中分配一
個對象實例，並將該值復制到新的對象中。
拆箱 是從 object 類型到值類型或從接口類型到實現該接口的值類型的顯式轉換。
-------------------
為何需要裝箱？
一種最普通的場景是，調用一個含類型為Object的參數的方法，該Object可支持任意為型，以便通用。當你需
要將一個值類型(如Int32)傳入時，需要裝箱。
另一種用法是，一個非泛型的容器，同樣是為了保證通用，而將元素類型定義為Object。於是，要將值類型數據
加入容器時，需要裝箱。
裝箱的內部操作。
裝箱： 對值類型在堆中分配一個對象實例，並將該值復制到新的對象中。按三步進行。
第一步：新分配托管堆內存(大小為值類型實例大小加上一個方法表指針和一個SyncBlockIndex)。
第二步：將值類型的實例字段拷貝到新分配的內存中。
第三步：返回托管堆中新分配對象的地址。這個地址就是一個指向對象的引用了。
拆箱：檢查對象實例，確保它是給定值類型的一個裝箱值。將該值從實例復制到值類型變量
中。
裝箱/拆箱對執行效率的影響(如何優化效率)
裝箱時,生成的是全新的引用對象,這會有時間損耗,也就是造成效率降低。 那該如何做呢？
避免裝箱的方法：
1、通過重載函數來避免。
2、通過泛型來避免。
凡事並不能絕對，假設你想改造的代碼為第三方程序集，你無法更改，那你只能是裝箱了
。 對於裝箱/拆箱代碼的優化，由於C#中對裝箱和拆箱都是隱式的，所以，根本的方法是對
代碼進行分析，而分析最直接的方式是了解原理結何查看反編譯的IL代碼。比如：在循環體
中可能存在多余的裝箱，你可以簡單采用提前裝箱方式進行優化。
對裝箱/拆箱更進一步的了解 裝箱/拆箱並不如上面所講那么簡單明了，
比如：裝箱時,變為引用對象,會多出一個方法表指針,這會有何用處呢？ 通過示例來進一步探討。
例子:
Struct A : ICloneable
{
public Int32 x;
public override String ToString()
{
return String.Format(”{0}”,x);
}
public object Clone()
{
return MemberwiseClone();
}
}
static void main()
{
A a;
a.x = 100;
Console.WriteLine(a.ToString());
Console.WriteLine(a.GetType());
A a2 = (A)a.Clone();
ICloneable c = a2; Ojbect o = c.Clone();
}
：a.ToString()。編譯器發現A重寫了ToString方法，會直接調用ToString的指令。因為A是值類型，編譯器不會出現多態行為。因此，直接調用，不裝箱。(注：ToString是A的基類System.ValueType的方法)
：a.GetType()，GetType是繼承於System.ValueType的方法，要調用它，需要一個方法表指針，於是a將被裝箱，從而生成方法表指針，調用基類的System.ValueType。(補一句，所有的值類型都是繼承於System.ValueType的)。
：a.Clone()，因為A實現了Clone方法，所以無需裝箱。 5.3：ICloneable轉型：當a2為轉為接口類型時，必須裝箱，因為接口是一種引用類型。
：c.Clone()。無需裝箱，在托管堆中對上一步已裝箱的對象進行調用。
附：其實上面的基於一個根本的原理，因為未裝箱的值類型沒有方法表指針，所以，不能通過值類型來調用其上繼承的虛方法。另外，接口類型是一個引用類型。對此，我的理解，該方法表指針類似C++的虛函數表指針，它是用來實現引用對象的多態機制的重要依據。
如何更改已裝箱的對象?
對於已裝箱的對象，因為無法直接調用其指定方法，所以必須先拆箱，再調用方法，但再次拆箱，會生成新的棧
實例，而無法修改裝箱對象。有點暈吧，感覺在說繞口令。還是舉個例子來說：
(在上例中追加change方法)
public void Change(Int32 x)
{
this.x = x;
}
//調用：
A a = new A();
a.x = 100;
Object o = a; //裝箱成o，下面，想改變o的值。
((A)o).Change(200); //改掉了嗎？沒改掉。 沒改掉的原因是o在拆箱時，生成的是臨時的棧實例A，所以，改
動是基於臨時A的，並未改到裝箱對象。
(附：在托管C++中，允許直接取加拆箱時第一步得到的實例引用，而直接更改，但C#不行。) 那該如何是好？ 嗯，
通過接口方式，可以達到相同的效果。 實現如下：
interface IChange
{
void Change(Int32 x);
}
struct A : IChange
{
…
}
//調用：
((IChange)o).Change(200);//改掉了嗎？改掉了。 為啥現在可以改？ 在將o轉型為IChange時，這里不會進行再
次裝箱，當然更不會拆箱，因為o已經是引用類型，再因為它是IChange類型，所以可以直接調用Change，於是，更
改的也就是已裝箱對象中的字段了，達到期望的效果。
-------------------------------------------------------------------------------------------------------------
-------------------------------------------------------------------------------------------------------------
-------------------------------------------------------------------------------------------------------------
附錄：(轉自http://www.cnblogs.com/hunts/archive/2007/01/19/boxing_unboxing.html和
http://www.cnblogs.com/cry/archive/2009/03/13/1410903.html）
a、裝箱
一個很簡單的例子。新建一個控制台程序，在Main()里面就寫兩句話。
int i = 13;
object ob = i;
編譯。然后用.net 提供的工具ILDASM.exe（MSIL Disassembler ）查看新生產這個程序的配件代碼（Microsoft intermediate language ，MSIL。順帶說一句.net framework SDK除了這個MSIL的反匯編工具，當然還提供了匯編工具ILASM.exe，可以使用MSIL編寫程序，當然。。誰也不會沒事這么干。那個反匯編工具倒是挺有用，可以了解一些底層機制）
用那個工具查看一下編譯后程序的Main(string[] args)方法，顯示如下（我現在用的時.net framework 2.0可能MSIL代碼顯示出來的和原來的1.0或者1.1稍有不同，不過沒關系核心沒變）：
.method private hidebysig static void Main(string[] args) cil managed
{
.entrypoint
// Code size 12 (0xc)
.maxstack 1
.locals init ([0] int32 i,
[1] object ob)
IL_0000: nop
IL_0001: ldc.i4.s 13
IL_0003: stloc.0
IL_0004: ldloc.0
IL_0005: box [mscorlib]System.Int32
IL_000a: stloc.1
IL_000b: ret
} // end of method Program::Main
稍微解釋一下：
(1)先注意 .locals ，定義了兩個類型分別為int32 和object 的局部變量
(2)然后看 IL_0001處，ldc是個指令，后面的i4.s指出作為32位（4個字節）整數被壓入堆棧。而壓入的值就是13
(3)下面的stloc把上面的值從堆棧彈出給局部變量i,這里的.0是指彈出給到第一個局部變量中，也就是i了
(4)這個值（13），被彈出后，就被裝載回堆棧，也就是后面IL_0004行的ldloc命令做的事情
(5)然后使用CIL（Common Language Infrastructure ）box將這個值轉換為引用類型。裝箱嘍～
(6)stloc.1根據（3）的解釋就好理解了，就是把box返回值彈出給第二個局部變量ob中。
但是這個box指令內部又發生了什么呢？有牛人告訴了我們。
(1)在堆上分配內存。因為值類型最終有一個對象代表，所有堆上分配的內存量必須是值類型的大小加上容納此對象及其內部結構（比如虛擬方法表）所需的內存量。
(2)值類型的值被復制到新近分配的內存中
(3)新近分配的對象地址被放到堆棧上，現在它指向一個引用類型
b、拆箱
在剛才程序的基礎上，再加一句話變成，編譯：
int i = 13;
object ob = i;
int j = (int)ob;
在裝箱的時候，並不需要顯示類型轉換。但在拆箱時需要類型轉換。這是因為在拆箱時對象可以被轉換為任何類型。看看MSIL代碼變成這德行了：
.method private hidebysig static void Main(string[] args) cil managed
{
.entrypoint
// Code size 19 (0x13)
.maxstack 1
.locals init ([0] int32 i,
[1] object ob,
[2] int32 j)
IL_0000: nop
IL_0001: ldc.i4.s 13
IL_0003: stloc.0
IL_0004: ldloc.0
IL_0005: box [mscorlib]System.Int32
IL_000a: stloc.1
IL_000b: ldloc.1
IL_000c: unbox.any [mscorlib]System.Int32
IL_0011: stloc.2
IL_0012: ret
} // end of method Program::Main
整個流程就不再重復敘述了，參照前面的解釋現在這個過程應該能看明白。
說說拆箱unbox的內部過程：
(1)因為一個對象將被轉換，所以編譯器必須先判斷堆棧上指向合法對象的地址，以及這個對象類型是否可以轉換為MSL unbox指令調用中指定的值類型。如果檢查失敗就拋出InvalidCastException異常。
(2)校驗通過后，就返回指向對象內的值的指針。可以看出，裝箱操作會創建轉換類型的副本，而拆箱就不會。不過注意一下，在我們裝箱的時候是先把變量i的值復制了一份賦給ob的，所變量j拿到的是ob這個變量的引用。也就是后面再改變i的值並不會影響j的值，但是改變ob的值就會。
c、再來一個稍微復雜點的例子，有如下代碼：
int i = 13;
object ob = i;
Console.WriteLine(i + "," + (Int32)ob);
這里做了幾次裝箱和拆箱操作呢？我開始想當然的以為是1次裝1次拆箱操作了，可實際上確是3次裝箱1次拆箱操作！先看看MSIL代碼：
.method private hidebysig static void Main(string[] args) cil managed
{
.entrypoint
// Code size 45 (0x2d)
.maxstack 3
.locals init ([0] int32 i,
[1] object ob)
IL_0000: nop
IL_0001: ldc.i4.s 13
IL_0003: stloc.0
IL_0004: ldloc.0
IL_0005: box [mscorlib]System.Int32
IL_000a: stloc.1
IL_000b: ldloc.0
IL_000c: box [mscorlib]System.Int32
IL_0011: ldstr ","
IL_0016: ldloc.1
IL_0017: unbox.any [mscorlib]System.Int32
IL_001c: box [mscorlib]System.Int32
IL_0021: call string [mscorlib]System.String::Concat(object,
object,
object)
IL_0026: call void [mscorlib]System.Console::WriteLine(string)
IL_002b: nop
IL_002c: ret
} // end of method Program::Main
(1)前面好說，跟前面一樣 object ob = i;引起了一次裝箱操作也就是 IL_0005處代碼。
(2)后面可以看出Console.WriteLine方法調用的是單個String作為參數的版本。因此上面調用了String.Concat方法將i + "," + (Int32)ob這3個值連接產生單個String再傳給WriteLine。
(3)String.Concat的重載版本里面找到最匹配的就是Concat(object, object,object)。這樣為了匹配這3個參數：
(3.1) IL_000c處代碼，第一個參數i被裝箱
(3.2)IL_0011 處ldstr "," 就是將字符串'，'壓入堆棧
(3.3)然后 IL_0017 (int32)ob引起了一次拆箱操作
(3.4)我們可憐的(int32)ob，又為了匹配Concat的參數，再次被裝箱(IL_001c)
明顯后面那個(int32)ob造成了一次不必要的拆箱和裝箱操作！所以正因為.net的自動類型處理能力，還是小心地注意一下寫法，否則就會引起不必有的性能損失。
下面舉類似的小例子
還是個那個控制台代碼寫成這樣
static ArrayList al;
static void Main(string[] args)
{
int i = 13;
al = new ArrayList();
al.Add(i);
Console.WriteLine("{0}", i);
}
MSIL命令如下：
.method private hidebysig static void Main(string[] args) cil managed
{
.entrypoint
// Code size 49 (0x31)
.maxstack 2
.locals init ([0] int32 i)
IL_0000: nop
IL_0001: ldc.i4.s 13
IL_0003: stloc.0
IL_0004: newobj instance void [mscorlib]System.Collections.ArrayList::.ctor()
IL_0009: stsfld class [mscorlib]System.Collections.ArrayList ConsoleApplication1.Program::al
IL_000e: ldsfld class [mscorlib]System.Collections.ArrayList ConsoleApplication1.Program::al
IL_0013: ldloc.0
IL_0014: box [mscorlib]System.Int32
IL_0019: callvirt instance int32 [mscorlib]System.Collections.ArrayList::Add(object)
IL_001e: pop
IL_001f: ldstr "{0}"
IL_0024: ldloc.0
IL_0025: box [mscorlib]System.Int32
IL_002a: call void [mscorlib]System.Console::WriteLine(string,
object)
IL_002f: nop
IL_0030: ret
} // end of method Program::Main
其他的都不用管，看懂了前面我說的，那么這里就知道因為ArrayList.Add(object)做了一次裝箱和Console.WriteLine(string,object)又做了一次裝箱。如果我們換一種寫法，把程序改成這樣：
static ArrayList al;
static void Main(string[] args)
{
int i = 13;
object ob = i;
al = new ArrayList();
al.Add(ob);
Console.WriteLine("{0}", ob);
}
MSIL就變成：
.method private hidebysig static void Main(string[] args) cil managed
{
.entrypoint
// Code size 46 (0x2e)
.maxstack 2
.locals init ([0] int32 i,
[1] object ob)
IL_0000: nop
IL_0001: ldc.i4.s 13
IL_0003: stloc.0
IL_0004: ldloc.0
IL_0005: box [mscorlib]System.Int32
IL_000a: stloc.1
IL_000b: newobj instance void [mscorlib]System.Collections.ArrayList::.ctor()
IL_0010: stsfld class [mscorlib]System.Collections.ArrayList ConsoleApplication1.Program::al
IL_0015: ldsfld class [mscorlib]System.Collections.ArrayList ConsoleApplication1.Program::al
IL_001a: ldloc.1
IL_001b: callvirt instance int32 [mscorlib]System.Collections.ArrayList::Add(object)
IL_0020: pop
IL_0021: ldstr "{0}"
IL_0026: ldloc.1
IL_0027: call void [mscorlib]System.Console::WriteLine(string,
object)
IL_002c: nop
IL_002d: ret
} // end of method Program::Main