使用vbs腳本進行批量編碼轉換

使用vbs腳本進行批量編碼轉換

 

最近需要使用SourceInsight查看分析在Linux系統下開發的項目代碼，我們知道Linux系統中文本文件默認編碼格式是UTF-8，而Windows中文系統中的默認編碼格式是Gb2312。系統內的編碼格式有所區別倒無傷大雅，關鍵的是SourceInsight竟不支持UTF-8，導致項目代碼內的中文注釋全部亂碼！

既然SourceInsight不支持UTF-8編碼的文件，那我們就得想辦法將UTF-8的代碼文件轉化為GB2312編碼的。首先想到的是到網上搜一下“批量編碼轉換工具”，結果下載后發現編碼轉換后的文件總是出現亂碼，可能是工具的bug吧。既然不能使用工具轉換，那就自己寫一個程序進行編碼轉換，但是細想一下覺得C++/java的編碼轉換程序寫起來又比較啰嗦，要是在Linux下寫一個shell腳本就能輕松搞定了。還好Windows下有vbs腳本可以幫助我們輕松達到這個目的。

'-------------------------------------------------

'函數名稱:ReadFile

'作用:利用AdoDb.Stream對象來讀取各種格式的文本文件

'-------------------------------------------------

 

Function ReadFile(FileUrl, CharSet)

    Dim Str

    Set stm = CreateObject("Adodb.Stream")

    stm.Type = 2

    stm.mode = 3

    stm.charset = CharSet

    stm.Open

    stm.loadfromfile FileUrl

    Str = stm.readtext

    stm.Close

    Set stm = Nothing

    ReadFile = Str

End Function

我們使用ReadFile函數讀取文件，其中FileUrl指定文件的路徑，CharSet指定文件的原始編碼格式，使用adodb.stream對象讀取文件內容到Str。

'-------------------------------------------------

'函數名稱:WriteToFile

'作用:利用AdoDb.Stream對象來寫入各種格式的文本文件

'-------------------------------------------------

 

Function WriteToFile (FileUrl, Str, CharSet)

    Set stm = CreateObject("Adodb.Stream")

    stm.Type = 2

    stm.mode = 3

    stm.charset = CharSet

    stm.Open

    stm.WriteText Str

    stm.SaveToFile FileUrl, 2

    stm.flush

    stm.Close

    Set stm = Nothing

End Function

然后使用WriteToFile將Str寫回原文件FileUrl，並設定新的編碼CharSet。

'-------------------------------------------------

'函數名稱:ConvertFile

'作用:將一個文件進行編碼轉換

'-------------------------------------------------

 

Function ConvertFile(FileUrl)

    Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)

End Function

這樣ConvertFile對上述兩個函數封裝，實現文件FileUrl的編碼轉換，其中原始編碼SrcCode與目的編碼DestCode為全局變量。

如果僅對一個文件進行編碼轉換，我們不必這么大費周章。我們希望能對任意的文件或文件夾內的所有文件進行編碼轉換，達到批量轉換的目的。

'-------------------------------------------------

'函數名稱:ConvertDir

'作用:將任意目錄內的文件進行編碼轉換

'-------------------------------------------------

 

Function ConvertDir(DirUrl)

    If fs.FileExists(DirUrl) Then 

       Call ConvertFile(DirUrl)

    Else

       Call SearchDir(DirUrl)

    End If

End Function

函數ConvertDir對任意路徑的文件/文件夾進行編碼轉換，使用scripting.filesystemobject對象的FileExists函數判斷路徑對應的是文件還是文件夾，如果是文件則直接調用ConvertFile進行編碼轉換，否則調用SearchDir處理文件夾。

'-------------------------------------------------

'函數名稱:SearchDir

'作用:遞歸查找目錄內的文件，進行編碼轉換

'-------------------------------------------------

 

Function SearchDir(path)   

    Set folder = fs.getfolder(path)

    Set subfolders = folder.subfolders

    Set Files = folder.Files   

    For Each i In Files

       Call ConvertFile(i.path)

    Next   

    For Each j In subfolders       

       Call SearchDir(j.path)

    Next

End Function

函數SearchDir是遞歸的，首先調用getfolder創建文件夾對象，然后取出文件夾內的子文件夾集合subfolders和子文件集合files。對於每個子文件，直接調用ConvertFile進行編碼轉換即可，而對於每個子文件夾，則遞歸調用SearchDir重復處理。

'-------------------------------------------------

'設置編碼：默認 utf-8  --> gb2312

'-------------------------------------------------

 

SrcCode="utf-8"

DestCode="gb2312"

 

'-------------------------------------------------

'解析參數

'-------------------------------------------------

 

Set fs = CreateObject("scripting.filesystemobject")

Set objArgs = WScript.Arguments

If objArgs.Count>0 Then

    For I = 0 To objArgs.Count - 1

       FileUrl = objArgs(I)

       Call ConvertDir(FileUrl)

    Next

Else

    MsgBox "沒有文件/文件夾被拖入！"

    wscript.quit

End If

MsgBox "轉換成功！"

最后通過解析腳本文件的參數，由於每個參數對應一個文件/文件夾的路徑，將之傳遞給ConvertDir即可。這里默認的是將UTF-8編碼轉化為GB2312編碼，讀者可以根據自身需要自行修改。

將上述代碼保存為ConvertCode.vbs，只需要將任意多個文件選中拖動到該腳本文件上即可。或者使用命令行。

> ConvertCode.vbs [filepath]

需要注意的是文件編碼是就地轉換的，在轉換之前最好將原文件/文件夾進行備份。

最后附上腳本文件的所有代碼。

 
            
            ' 
            /*=========================================================== 
            
' 
             * Intro        把要轉換的多個文件/文件夾拖到該文件上即可 
            
' 
             * FileName     ConvertCode.vbs 
            
' 
             * Author       Florian 
            
' 
             * Version      v1.0 
            
' 
             * WEB           http://www.cnblogs.com/fanzhidongyzby 
            
' 
             * Email        [e-mail] 
            
' 
             * LastModify  2014-06-11 00:39:58 
            
' 
             *==========================================================*/ 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            設置編碼：默認    utf-8    -->    gb2312 
            
' 
            ------------------------------------------------- 
            
 
            
SrcCode= 
            " 
            utf-8 
            " 
            
DestCode= 
            " 
            gb2312 
            " 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            解析參數 
            
' 
            ------------------------------------------------- 
            
 
            
 
            Set fs =  
            CreateObject( 
            " 
            scripting.filesystemobject 
            ") 
            
 
            Set objArgs = WScript.Arguments 
            
 
            If objArgs.Count> 
            0  
            Then 
            
     
            For I =  
            0  
            To objArgs.Count -  
            1 
            
        FileUrl = objArgs(I) 
            
         
            Call ConvertDir(FileUrl) 
            
     
            Next 
            
 
            Else 
            
     
            MsgBox  
            " 
            沒有文件/文件夾被拖入！ 
            " 
            
    wscript.quit 
            
 
            End  
            If 
            
 
            MsgBox     
            " 
            轉換成功！ 
            " 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            函數名稱:ConvertDir 
            
' 
            作用:將任意目錄內的文件進行編碼轉換 
            
' 
            ------------------------------------------------- 
            
 
            
 
            Function ConvertDir(DirUrl) 
            
     
            If fs.FileExists(DirUrl)  
            Then   
            
         
            Call ConvertFile(DirUrl) 
            
     
            Else 
            
         
            Call SearchDir(DirUrl) 
            
     
            End  
            If 
            
 
            End Function 
            
 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            函數名稱:SearchDir 
            
' 
            作用:遞歸查找目錄內的文件，進行編碼轉換 
            
' 
            ------------------------------------------------- 
            
 
            
 
            Function SearchDir(path)     
            
     
            Set folder = fs.getfolder(path) 
            
     
            Set subfolders = folder.subfolders 
            
     
            Set Files = folder.Files     
            
     
            For  
            Each i  
            In Files 
            
         
            Call ConvertFile(i.path) 
            
     
            Next     
            
     
            For  
            Each j  
            In subfolders         
            
         
            Call SearchDir(j.path) 
            
     
            Next 
            
 
            End Function 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            函數名稱:ConvertFile 
            
' 
            作用:將一個文件進行編碼轉換 
            
' 
            ------------------------------------------------- 
            
 
            
 
            Function ConvertFile(FileUrl) 
            
     
            Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode) 
            
 
            End Function 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            函數名稱:ReadFile 
            
' 
            作用:利用AdoDb.Stream對象來讀取各種格式的文本文件 
            
' 
            ------------------------------------------------- 
            
 
            
 
            Function ReadFile(FileUrl, CharSet) 
            
     
            Dim  
            Str 
            
     
            Set stm =  
            CreateObject( 
            " 
            Adodb.Stream 
            ") 
            
    stm.Type =  
            2 
            
    stm.mode =  
            3 
            
    stm.charset = CharSet 
            
    stm.Open 
            
    stm.loadfromfile FileUrl 
            
     
            Str = stm.readtext 
            
    stm.Close 
            
     
            Set stm =  
            Nothing 
            
    ReadFile =  
            Str 
            
 
            End Function 
            
 
            
 
            ' 
            ------------------------------------------------- 
            
' 
            函數名稱:WriteToFile 
            
' 
            作用:利用AdoDb.Stream對象來寫入各種格式的文本文件 
            
' 
            ------------------------------------------------- 
            
 
            
 
            Function WriteToFile (FileUrl,  
            Str, CharSet) 
            
     
            Set stm =  
            CreateObject( 
            " 
            Adodb.Stream 
            ") 
            
    stm.Type =  
            2 
            
    stm.mode =  
            3 
            
    stm.charset = CharSet 
            
    stm.Open 
            
    stm.WriteText  
            Str 
            
    stm.SaveToFile FileUrl,  
            2 
            
    stm.flush 
            
    stm.Close 
            
     
            Set stm =  
            Nothing 
            
 
            End Function