VB.NET中Module的概念

今天學習VB.NET，發現VB.NET里面有一個Module的東西，如下圖(圖-1)所示：

圖-1

上網查了一下VB.NET里面的Module，才發現這是學習VB.NET遇到的第一個典型的問題就是：為什么VB.NET中會有一個Module的東西，而在C#等語言中是沒有的呢？

首先，這是一個歷史原因。早先的VB語言都有模塊和類模塊的概念。所謂模塊一般就是存放公用的一些方法(Sub)或者函數(Function)，而類模塊，相當於就是我們經常所說的類的概念。 

模塊(Module)里面可以直接有方法，這些方法自動就是靜態的（或者稱為共享的——VB.NET中的關鍵字是Shared)，這些方法可以直接調用，所以Module是無法實例化，也沒有必要實例化的。

模塊無法繼承，也無法實現接口。

模塊里面可以有類，但其實這個類並不需要真的通過模塊作為前綴來引用。所以模塊有點虛的概念

模塊可以被組織到命名空間中去，因為模塊其實是個虛的，所以它的方法也可以直接外層的命名空間調用

Module代碼范例：

'用命名空間封裝Module
Namespace VBModuleTest
    ''' <summary>
    ''' 模塊無法繼承，無法實現接口
    ''' </summary>
    ''' <remarks></remarks>
    Module ModuleTest
        ''' <summary>
        ''' 模塊里面的方法都是靜態的，無需實例化，也無從實例化
        ''' </summary>
        ''' <remarks></remarks>
        Sub Main()
            'new一個Class1實例
            'Dim clazz As Class1 = New Class1這樣也是對的
            Dim clazz As Class1 = New Class1()
            clazz.Name = "Class1類"
            Console.WriteLine(clazz.Name)
            Console.WriteLine(clazz.GetClassName())
            Console.ReadKey()
        End Sub
        ''' <summary>
        ''' 有返回值的方法，用Function來聲明
        ''' </summary>
        ''' <returns></returns>
        ''' <remarks></remarks>
        Public Function Test1() As String
            Console.WriteLine("這個是Module里面的Test1方法")
            Return ""
        End Function
        ''' <summary>
        ''' 無返回值的方法，用Sub來聲明
        ''' </summary>
        ''' <remarks></remarks>
        Public Sub Test2()
            Console.WriteLine("這個是Module里面的Test2方法")
        End Sub

        ''' <summary>
        ''' 類型可以放在模塊里面，但主要的現實意義在於分類存放而已，放在模塊里面並不影響該類型對外的引用。
        ''' 例如我們並不一定需要用VBModuleTest.ModuleTest.Class1，
        ''' 而是直接通過VBModuleTest.Class1就可以對其進行引用
        ''' </summary>
        ''' <remarks></remarks>
        Public Class Class1 : Implements IComparable
            ''' <summary>
            ''' 聲明屬性
            ''' </summary>
            ''' <remarks></remarks>
            Private _name As String
            Public Property Name() As String
                Get
                    Return _name
                End Get
                Set(ByVal value As String)
                    Me._name = value
                End Set
            End Property

            ''' <summary>
            ''' 聲明方法
            ''' </summary>
            ''' <returns></returns>
            ''' <remarks></remarks>
            Public Function GetClassName() As String
                Test1()
                ModuleTest.Test2()
                Return Me.GetType().ToString()
            End Function

            ''' <summary>
            ''' 實現接口中的方法
            ''' </summary>
            ''' <param name="obj"></param>
            ''' <returns></returns>
            ''' <remarks></remarks>
            Public Function CompareTo(ByVal obj As Object) As Integer Implements System.IComparable.CompareTo
                Return 1
            End Function
        End Class
    End Module
End Namespace

這里的代碼只是純粹為演示目的而寫的，沒有任何具體意義 。