SQLSERVER清空(Truncate)被外鍵引用的數據表

前言：我們知道SQLSERVER清空數據表有兩種方式Delete和Truncate，當然兩者的不同大家也都知道(不清楚的可以MSDN)。不過這個錯誤“Cannot truncate table  because it is being referenced by a FOREIGN KEY” 相信大家也都遇到過，解決的已解決，未解決的且看下文。

如何解決

開始我以為只要將外鍵Disable掉就可以了，事實證明是沒用的。其實MSDN已經明確告訴了我們：

不能對以下表使用 TRUNCATE TABLE：

• 由 FOREIGN KEY 約束引用的表。（您可以截斷具有引用自身的外鍵的表。）
• 參與索引視圖的表。
• 通過使用事務復制或合並復制發布的表。

對於具有以上一個或多個特征的表，請使用 DELETE 語句。

TRUNCATE TABLE 不能激活觸發器，因為該操作不記錄各個行刪除

難道我真的要用Delete嗎？可我真的不想用Delete。原因就在於Truncate的優點，MSDN說：

與 DELETE 語句相比，TRUNCATE TABLE 具有以下優點：

• 所用的事務日志空間較少。
  DELETE 語句每次刪除一行，並在事務日志中為所刪除的每行記錄一個項。TRUNCATE TABLE 通過釋放用於存儲表數據的數據頁來刪除數據，並且在事務日志中只記錄頁釋放。
• 使用的鎖通常較少。
  當使用行鎖執行 DELETE 語句時，將鎖定表中各行以便刪除。TRUNCATE TABLE 始終鎖定表和頁，而不是鎖定各行。
• 如無例外，在表中不會留有任何頁。
  執行 DELETE 語句后，表仍會包含空頁。(略去例如)

好了，下面就來說一下解決方法。

解決方案

1.使用Delete

a) 先Delete依賴表（或叫從表）

b) 再Delete被依賴表（或叫主表）

2.使用Truncate

a) 先備份依賴表外鍵

b) 刪除依賴表外鍵

c) Truncate主表

d) 重新創建依賴表外鍵

一段腳本

其實是一個使用Truncate進行處理的存儲過程，思路見上。

USE <YOUR DB>
GO

CREATE PROCEDURE [dbo].[usp_Truncate_Table]
  @TableToTruncate VARCHAR(64)
AS 

BEGIN

SET NOCOUNT ON

--==變量定義
DECLARE @i int
DECLARE @Debug bit
DECLARE @Recycle bit
DECLARE @Verbose bit
DECLARE @TableName varchar(80)
DECLARE @ColumnName varchar(80)
DECLARE @ReferencedTableName varchar(80)
DECLARE @ReferencedColumnName varchar(80)
DECLARE @ConstraintName varchar(250)

DECLARE @CreateStatement varchar(max)
DECLARE @DropStatement varchar(max)   
DECLARE @TruncateStatement varchar(max)
DECLARE @CreateStatementTemp varchar(max)
DECLARE @DropStatementTemp varchar(max)
DECLARE @TruncateStatementTemp varchar(max)
DECLARE @Statement varchar(max)

 SET @Debug = 0--(0:將執行相關語句|1:不執行語句)
 SET @Recycle = 0--(0:不創建/不清除存儲表|1:將創建/清理存儲表)
 set @Verbose = 1--(1:每步執行均打印消息|0:不打印消息)

 SET @i = 1
    SET @CreateStatement = 'ALTER TABLE [dbo].[<tablename>]  WITH NOCHECK ADD  CONSTRAINT [<constraintname>] FOREIGN KEY([<column>]) REFERENCES [dbo].[<reftable>] ([<refcolumn>])'
    SET @DropStatement = 'ALTER TABLE [dbo].[<tablename>] DROP CONSTRAINT [<constraintname>]'
    SET @TruncateStatement = 'TRUNCATE TABLE [<tablename>]'

-- 創建外鍵臨時表
IF OBJECT_ID('tempdb..#FKs') IS NOT NULL
    DROP TABLE #FKs

-- 獲取外鍵
SELECT ROW_NUMBER() OVER (ORDER BY OBJECT_NAME(parent_object_id), clm1.name) as ID,
       OBJECT_NAME(constraint_object_id) as ConstraintName,
       OBJECT_NAME(parent_object_id) as TableName,
       clm1.name as ColumnName, 
       OBJECT_NAME(referenced_object_id) as ReferencedTableName,
       clm2.name as ReferencedColumnName
  INTO #FKs
  FROM sys.foreign_key_columns fk
       JOIN sys.columns clm1 ON fk.parent_column_id = clm1.column_id AND fk.parent_object_id = clm1.object_id
       JOIN sys.columns clm2 ON fk.referenced_column_id = clm2.column_id AND fk.referenced_object_id= clm2.object_id
 --WHERE OBJECT_NAME(parent_object_id) not in ('//tables that you do not wont to be truncated')
 WHERE OBJECT_NAME(referenced_object_id) = @TableToTruncate
 ORDER BY OBJECT_NAME(parent_object_id)

-- 外鍵操作(刪除|重建)表
IF Not EXISTS(SELECT 1 FROM INFORMATION_SCHEMA.TABLES WHERE TABLE_NAME = 'Internal_FK_Definition_Storage')
BEGIN
    IF @Verbose = 1
        PRINT '1. 正在創建表(Internal_FK_Definition_Storage)...'
    CREATE TABLE [Internal_FK_Definition_Storage] 
    (
        ID int not null identity(1,1) primary key,
        FK_Name varchar(250) not null,
        FK_CreationStatement varchar(max) not null,
        FK_DestructionStatement varchar(max) not null,
        Table_TruncationStatement varchar(max) not null
    ) 
END 
ELSE
BEGIN
    IF @Recycle = 0
    BEGIN
        IF @Verbose = 1
        PRINT '1. 正在清理表(Internal_FK_Definition_Storage)...'
        TRUNCATE TABLE [Internal_FK_Definition_Storage]    
    END
    ELSE
        PRINT '1. 正在清理表(Internal_FK_Definition_Storage)...'
END

IF @Recycle = 0
BEGIN
    IF @Verbose = 1
        PRINT '2. 正在備份外鍵定義...'           
    WHILE (@i <= (SELECT MAX(ID) FROM #FKs))
    BEGIN
        SET @ConstraintName = (SELECT ConstraintName FROM #FKs WHERE ID = @i)
        SET @TableName = (SELECT TableName FROM #FKs WHERE ID = @i)
        SET @ColumnName = (SELECT ColumnName FROM #FKs WHERE ID = @i)
        SET @ReferencedTableName = (SELECT ReferencedTableName FROM #FKs WHERE ID = @i)
        SET @ReferencedColumnName = (SELECT ReferencedColumnName FROM #FKs WHERE ID = @i)

        SET @DropStatementTemp = REPLACE(REPLACE(@DropStatement,'<tablename>',@TableName),'<constraintname>',@ConstraintName)
        SET @CreateStatementTemp = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@CreateStatement,'<tablename>',@TableName),'<column>',@ColumnName),'<constraintname>',@ConstraintName),'<reftable>',@ReferencedTableName),'<refcolumn>',@ReferencedColumnName)
        SET @TruncateStatementTemp = REPLACE(@TruncateStatement,'<tablename>',@TableName) 

        INSERT INTO [Internal_FK_Definition_Storage]
        SELECT @ConstraintName, @CreateStatementTemp, @DropStatementTemp, @TruncateStatementTemp
        
        SET @i = @i + 1
        
        IF @Verbose = 1
            PRINT '  > 已備份外鍵:[' + @ConstraintName + '] 所屬表: [' + @TableName + ']'
    END   
END   
ELSE 
    PRINT '2. 正在備份外鍵定義...'

IF @Verbose = 1
    PRINT '3. 正在刪除外鍵...'
BEGIN TRAN    
BEGIN TRY
SET @i = 1
WHILE (@i <= (SELECT MAX(ID) FROM [Internal_FK_Definition_Storage]))
BEGIN
    SET @ConstraintName = (SELECT FK_Name FROM [Internal_FK_Definition_Storage] WHERE ID = @i)
    SET @Statement = (SELECT FK_DestructionStatement FROM [Internal_FK_Definition_Storage] WITH (NOLOCK) WHERE ID = @i)
    IF @Debug = 1 
        PRINT @Statement
    ELSE
        EXEC(@Statement)
    SET @i = @i + 1
    IF @Verbose = 1
        PRINT '  > 已刪除外鍵:[' + @ConstraintName + ']'
END     

IF @Verbose = 1
    PRINT '4. 正在清理數據表...'
--先清除該外鍵所在表(由於外鍵所在表仍可能又被其他外鍵所引用，因此需要循環遞歸處理)(注：本處理未實現)
--請不要使用下面注釋代碼
/*    
SET @i = 1
WHILE (@i <= (SELECT MAX(ID) FROM [Internal_FK_Definition_Storage]))
BEGIN
    SET @Statement = (SELECT Table_TruncationStatement FROM [Internal_FK_Definition_Storage] WHERE ID = @i)
    IF @Debug = 1 
        PRINT @Statement
    ELSE
        EXEC(@Statement)
    SET @i = @i + 1
    IF @Verbose = 1
        PRINT '  > ' + @Statement
END
*/

IF @Debug = 1 
    PRINT 'TRUNCATE TABLE [' + @TableToTruncate + ']'
ELSE
    EXEC('TRUNCATE TABLE [' + @TableToTruncate + ']')
IF @Verbose = 1
    PRINT '  > 已清理數據表[' + @TableToTruncate + ']'
    
IF @Verbose = 1
    PRINT '5. 正在重建外鍵...'
SET @i = 1
WHILE (@i <= (SELECT MAX(ID) FROM [Internal_FK_Definition_Storage]))
BEGIN
    SET @ConstraintName = (SELECT FK_Name FROM [Internal_FK_Definition_Storage] WHERE ID = @i)
    SET @Statement = (SELECT FK_CreationStatement FROM [Internal_FK_Definition_Storage] WHERE ID = @i)
    IF @Debug = 1 
        PRINT @Statement
    ELSE
        EXEC(@Statement)
    SET @i = @i + 1
    IF @Verbose = 1
    PRINT '  > 已重建外鍵:[' + @ConstraintName + ']'
END
    COMMIT
END TRY
BEGIN CATCH
    ROLLBACK 
    PRINT '出錯信息:'+ERROR_MESSAGE()
END CATCH
IF @Verbose = 1
    PRINT '6. 處理完成！'
END

如何使用

例子說明：清空整個數據庫

USE <YOUR DB>
GO

--==創建臨時表
IF(OBJECT_ID('TEMPDB..#TEMP')IS NOT NULL)
    DROP TABLE #TEMP

--==讀取數據庫表
SELECT SN=ROW_NUMBER()OVER(ORDER BY [name]ASC),TableName=[name]
INTO #TEMP
FROM sys.tables 
WHERE [name]<>'Internal_FK_Definition_Storage'

--SELECT * FROM #TEMP

--==開始處理
DECLARE @ROWS INT 
SELECT @ROWS=MAX(SN)FROM #TEMP
DECLARE @I INT
SET @I=1
DECLARE @TableName VARCHAR(64)
WHILE(@I<=@ROWS)
BEGIN
    IF(EXISTS(SELECT 1 FROM #TEMP WHERE SN=@I))
    BEGIN
        SELECT @TableName=TableName FROM #TEMP WHERE SN=@I
        EXEC [dbo].[usp_Truncate_Table] @TableToTruncate = @TableName
    END
    SET @TableName=N''
    SET @I=@I+1
END

 

結束語：文章無甚深淺，止乎於分享。如有錯誤，還望斧正。