前陣子U盤中毒了，搞得自己的電腦也中毒了，今天才發現我電腦里的文件夾不能隱藏了。google了一下，找到了如下的技術貼，發現第二種有用！
問題如圖：
出現該情況的原因：除了一些系統文件系統默認的之外，其他主要是由於U盤文件受病毒感染，盤內的文件夾變成了以.exe為后綴的文件，原文件夾即被強制設置成隱藏屬性如上圖所示的隱藏屬性不能更改。（文中操作均在WIN7系統下進行）
查看一般的隱藏文件夾的方法：如圖
點“工具”——“文件夾選項”——“查看”——選擇“顯示隱藏的文件、文件夾或驅動器”
解決方法一：點“開始”——在搜索欄輸入“cmd”按確定（進入命令提示符界面）——輸入“attrib 文件路徑及文件夾名 -s -h /s /d”后按Enter鍵（輸入文件路徑及文件夾名時可直接將文件夾拉至命令提示符窗口即可，不用手動輸入）
（比如attrib C:\Boot -s -h /s /d）如圖：，
，之后文件夾即可回復正常狀態。
相關參數解釋：attrib（顯示或更改文件屬性）， +r（設置只讀文件屬性）， -r（清除只讀文件屬性）， +a（設置存檔屬性）， -a（清除存檔屬性）
+s（設置系統文件屬性）， -s（清除系統文件屬性）， +h（設置隱藏文件屬性）， -h（清除隱藏文件屬性），
/s（將attrib和任意命令行選項應用到當前目錄及其所有子目錄中的匹配文件）， /d（將attrib和任意命令行選項應用到目錄）
該方法適合單個文件夾操作，關於使用attrib批量恢復的網上貌似說有，本人嘗試沒有成功。還有貌似可以通過修改注冊表信息來恢復的。
解決方法二：此法是網上大神所作，批量文件夾單個恢復均適用，快捷的批量取消和設置隱藏屬性和系統屬性，真是佩服那位大神，o(≧v≦)o~~好棒，對大神標表示感謝。
步驟：
1.右鍵新建一個txt文本文檔。
2.將后面提供的代碼復制粘貼到新建的txt文本文檔內並保存。
3.將該文本文檔后綴名.txt改為.bat，即該文檔變成了批處理文件/批處理腳本。
4.不是雙擊該批處理文件使用，而是將需要恢復的文件夾或文件拉到該批處理文件上，如圖：
將工作區這個文件拉到改成.bat后綴的原文本文檔圖標上， 之后顯示：
之后步驟一直選“2 去掉”項，然后“Enter”確定即可。要是要恢復整個U盤的文件夾，可直接將U盤那盤符拉到.bat那文件上，同原來一樣操作。
以下為需要保存到新建文本文檔的代碼：
@echo off&setlocal enableextensions enabledelayedexpansion
title 修改系統文件屬性和隱藏文件屬性
if "%~1"=="" (echo 你沒有拖入 任何磁盤或文件或文件夾
echo 請把 要處理的磁盤或文件或文件夾 拖到 批處理文件圖標
echo 不要 雙擊啟動 批處理&pause&goto :eof)
call:choose "設置隱藏文件屬性,請選擇:" 不改變 去掉 設置
(set h=)&(if !c! equ 2 set h=-)&(if !c! equ 3 set h=+)
call:choose "設置系統文件屬性,請選擇:" 不改變 去掉 設置
(set s=)&(if !c! equ 2 set s=-)&(if !c! equ 3 set s=+)
call:choose "設置應用范圍,請選擇:" 文件或文件夾自身屬性及第一級目錄內容屬性 文件夾第一級目錄內容屬性
for %%i in (%*) do (if !c! equ 1 call:attrib "%%~i"
for /f "delims=" %%j in ('dir /a /b "%%~i"') do call:attrib "%%~i\%%~j")
pause&goto :eof
:choose
(set c=)&(set n=)&for %%i in (%*) do echo !n! %%~i&set /a n+=1
(set /p c=)&(set /a c=c)&if !c! geq 0 if !c! leq !n! echo.&goto :eof
goto choose
:attrib
setlocal&(set a=)&(set a=%~a1)&if "!a!"=="" goto :eof
if not defined h if "!a:~3,1!"=="h" (set h=+) else (set h=-)
if not defined s if "!a:~4,1!"=="s" (set s=+) else (set s=-)
echo 正在處理: %~1&attrib !h!h !s!s "%~1"&goto :eof