SQLSERVER拯救某個時間點被誤刪除的數據

轉載自：http://blog.csdn.net/dba_huangzj/article/details/8491327

要拯救某個時間點被誤刪除的數據，需要你在那個時間點之前有一個完整數據庫備份。

而且，需要你的數據庫恢復模式為：“完整恢復模式”

如何查看你的數據庫恢復模式為完整恢復模式，運行下面SQL

SELECT  recovery_model, recovery_model_desc
FROM    sys.databases
WHERE   name = 'GPOSDB'

在創建完一個新數據庫之后，強烈建議做一次數據庫完整備份

-------------------------------------------------------------------華麗的分割線-----------------------------------------------------------------------

先創建測試表

/*
由於tempdb永遠為簡單恢復模式，所以不適合做案例。
這里使用我的測試機器里的數據庫GPOSDB
*/
USE [GPOSDB]
GO
IF OBJECT_ID('testRestore') IS NOT NULL 
    DROP TABLE testRestore
GO
CREATE TABLE testRestore
    (
      id INT IDENTITY(1, 1) ,
      NAME VARCHAR(50)
    );

插入測試數據

--插入測試數據：   
INSERT INTO testRestore(Name)
SELECT 'test1'
UNION ALL 
SELECT 'test2'
UNION ALL 
SELECT 'test3'
UNION ALL 
SELECT 'test4'
UNION ALL 
SELECT 'test5'
UNION ALL 
SELECT 'test6'
UNION ALL 
SELECT 'test7'
UNION ALL 
SELECT 'test8'

 

SELECT * FROM testRestore

先來一個數據庫完整備份，在22:32的時候完整備份數據庫

BACKUP DATABASE [GPOSDB]
TO DISK='D:\GPOSDB_FULLBACKUP2013-07-23.bak'
WITH INIT
go

模擬刪除表數據，這里使用waitfor time，目的是使刪除數據的時間准確一點，這里選擇22:34的時候刪除數據方便后面還原某個時間點之前的數據

USE [GPOSDB]
GO
WAITFOR TIME '22:34'
DELETE FROM dbo.testRestore

查詢一下數據是否刪除

USE [GPOSDB]
GO
SELECT * FROM dbo.testRestore

斷開與GPOSDB數據庫的連接，如果還有連接就kill掉連接，然后執行事務日志備份，在22:36的時候執行事務日志備份

--刪除了表中的數據之后最少要等3分鍾才執行下面SQL語句，不然的話等一下還原事務日志的時候會報錯
--必須斷開所有與GPOSDB數據庫的連接
USE master
GO
BACKUP LOG [GPOSDB] TO  DISK = N'D:\GPOSDB_LOGBACKUP2013-07-23.bak' WITH  NO_TRUNCATE , NOFORMAT,  NAME = N'GPOSDB-事務日志備份', SKIP,  NORECOVERY ,  STATS = 10, CHECKSUM
GO
DECLARE @backupSetId AS INT
SELECT  @backupSetId = position
FROM    msdb..backupset
WHERE   database_name = N'GPOSDB' AND backup_set_id = ( SELECT
                                                              MAX(backup_set_id)
                                                        FROM  msdb..backupset
                                                        WHERE database_name = N'GPOSDB'
                                                      )
IF @backupSetId IS NULL  --這里是驗證事務日志備份是否成功，如果沒有斷開與GPOSDB數據庫的連接備份事務日志可能會失敗
    BEGIN
        RAISERROR(N'驗證失敗。找不到數據庫“GPOSDB”的備份信息。', 16, 1)
    END
RESTORE VERIFYONLY FROM  DISK = N'D:\GPOSDB_LOGBACKUP2013-07-23.bak' WITH  FILE = @backupSetId
GO

--查詢是否備份成功
SELECT TOP 10 * FROM    msdb..backupset ORDER BY [backup_set_id] DESC 

還原數據庫完整備份

--數據庫處於正在還原狀態
RESTORE DATABASE [GPOSDB] FROM DISK='D:\GPOSDB_FULLBACKUP2013-07-23.bak' WITH replace, NORECOVERY 

 還原事務日志

--因為刪除數據是在'22:34' 所以還原到22:33
RESTORE LOG [GPOSDB] FROM DISK='D:\GPOSDB_LOGBACKUP2013-07-23.bak' WITH RECOVERY ,STOPAT='2013-7-23 22:33'

如果事務日志還原失敗的話，可以使用GUI界面

查看表中的數據

USE [GPOSDB]
GO
SELECT * FROM dbo.testRestore

 -----------------------------------------------------------華麗的分割線--------------------------------------------

要注意的兩個地方：

（1）如果你發現誤操作以后還有很多人做了操作，那么你還原成功后，別人的操作就會沖掉，所以發生誤操作后，要馬上停止別人對數據庫的操作。

（2）這個方法要對數據庫獨占