HSPICE常用分析類型
直流分析（DC Analysis）( 參見HSPICE User’s Manual （1）3-4 )
常用命令：
.OP 直流工作點分析
.NODESET 節點設置
.SENS 小信號靈敏度分析
.TF 小信號轉移函數分析
.DC 直流掃描
.OP
計算直流工作點，但其不控制偏置點分析的方法和偏置計算的結果。
.NODESET
在計算直流偏置點時，為使直流分析收斂，電路的某些節點或所有節點可以用.NODESET命令設置初始估計值。一旦建立了工作點，.NODESET語句在直流掃描分析和瞬態分析中將不再其任何作用。注意.NODESET和.IC命令不同。.IC命令在電路進行瞬態分析作工作點計算時為電路設置初始狀態。
Example：
.NODESET V(4)=1.5V V(6) = 0
.DC
格式：
.DC var1 start1 stop1 incr1 <var2 start2 stop2 inc2>
.DC var1 start1 stop1 incr1 <SWEEP var2 type np start2 stop2 >
.DC var1 start1 stop1 incr1 <SWEEP DATA＝datanm >
.DC DATA＝datanm <SWEEP var2 start2 stop2 incr2>
其中type可以為DEC、OCT、LIN或POI（List of Points）。
注意start的值可以比stop的值大，即掃描可以在兩個方向上進行，但inc只能為正值。
Examples：
.DC VIN 0 10 1
.DC VIN 0 10 1 VGS 0 5 1
.DC XVAL 1K 10K 0.5K SWEEP TEMP LIN 5 25 125
.DC TEMP POI 5 0 30 50 100 125
該語句將在五個溫度點進行直流掃描：0、30、50、100、150（單位：攝氏度）。
例1：直流參數掃描
電路圖：
**** t6.cir
****直流參數掃描
M1 1 2 0 0 NSS
VGS 2 0 DC 0V
VDD 1 0 DC 12V
.MODEL NSS NMOS LEVEL=3 RSH=0 TOX=275E-10 LD=.1E-6 XJ=.14E-6
+ CJ=1.6E-4 CJSW=1.8E-10 UO=550 VTO=1.022 CGSO=1.3E-10
+ CGDO=1.3E-10 NSUB=4E15 NFS=1E10
+ VMAX=12E4 PB=.7 MJ=.5 MJSW=.3 THETA=.06 KAPPA=.4 ETA=.14
.DC VDD 0 5 0.1 VGS 0 2 0.5
.PLOT DC I1(M1)
.END
波形：
1、 交流分析（AC Analysis）
常用命令：
.AC 交流分析
.NOISE 噪聲分析
.NET 網絡特性分析
格式：
.AC 交流分析
.AC type np fstart fstop
.AC type np fstart fstop <SWEEP var type np fstart fstop >
.AC type np fstart fstop <SWEEP var fstart fstop incr>
.AC type np fstart fstop <SWEEP DATA=datanm >
其中，np是交流掃描的點數；fstart是起始頻率；fstop是終止頻率。type可以為DEC、LIN、OCT、POI。
LIN為線性掃描，是從起始頻率到終止頻率的線性掃描，np是掃描中的總點數。下一個頻率值由當前一個頻率值加上一個常量得到。LIN在帶寬較窄時使用。
OCT為倍頻掃描，頻率以倍頻程進行對數掃描。np是倍頻程內的掃描點數。下一個頻率值由當前值乘以一個大於一的常數產生。OCT用於帶寬教窄的情形。
DEC為十倍頻掃描，它進行對數掃描。np是十倍頻程內的掃描點數。DEC用於帶寬特別寬的情況。
Examples：
.AC DEC 10 1K 100MEG
.AC DEC 10 1 10K SWEEP cload LIN 20 1pf 10pf
.NOISE 噪聲分析
.NOISE ovv srcnam inter
其中，ovv為節點電壓輸出變量，srcnam是產生等價輸入噪聲的獨立電壓源或電流源，inter是打印間隔。
.NET 網絡特性分析
單端口網絡：
.NET input <RIN = val>
.NET input <val>
雙端口網絡：
.NET Output Input < ROUT = val > < RIN = val >
Input 為輸入交流電壓源或電流源
Output 為輸出端，可以是電壓或電流
RIN 輸入電阻或電源內阻，用於計算輸出電阻
ROUT輸出電阻或負載電阻，用來計算收入阻抗
（詳細用法請參閱HSPICE User’s manual 3-14）
例：低通濾波器
***** t11.cir
.AC DEC 10 10 100MEG
vin 1 0 ac 1
r1 1 2 100
c1 2 0 30p
.end
波形如下：
2、 瞬態分析（Transient Analysis）
常用命令：
.IC 瞬態初始狀態
其一般格式為：
.IC V(1)=V1 V(2)=V2 ……
這些偏置點不影響直流分析和直流掃描中固定偏置點的計算。為了使IC命令有效，應在.TRAN語句中指定UIC。IC語句也可寫在元件后面，如C1 2 0 IC＝3。
.TRAN 瞬態分析
格式：
.TRAN tincr1 tstop1 <tincr2 tstop2 …><UIC>
.TRAN tincr1 tstop1 <tincr2 tstop2 …><SWEEP var pstart pstop pincr >
.TRAN tincr1 tstop1 <tincr2 tstop2 …><SWEEP var type np pstart pstop >
Examples:
.TRAN 1ns 100ns
.TRAN
例2：
**** t2.cir
****溫度掃描*****
R1 1 2 100
R2 0 1 100 TC1=0.05
V1I3 2 0 dc 5v
.tran 1ms 10ms sweep temp 20 60 20
.plot v(1)
.END
波形：
例3：
**** t3.cir
******電阻參數掃描
R1 1 2 rload
R2 0 1 100
V1I3 2 0 dc 5v
.tran 1ms 10ms sweep rload poi 3 100 200 300
.END
波形：
例4：
**** t5.cir
****IC命令
R2 1 2 20
C1 2 0 2.5U
VIN 1 0 dc 5v
.IC V(2)=4V
.TRAN 5US 1MS
.END
使用.IC命令仿真波形：
不使用.IC命令仿真波形：
由此可見，對於含有記憶性元件的電路，為正確反映電路特性，可采取以下措施：
（1） 采用.IC語句
（2） 電源采用分段線性源
3、 其他常用語句
.DATA
格式：
.DATA datanm pnam1 < pnam2 pnam3 ……>
+ pval1 < pval2 pval3……>
+ pval1’ <pval2’ pval3’……>
.ENDDATA
Examples:
.TRAN 1n 100n SWEEP DATA=devinf
.AC DEC 10 1hz 10khz SWEEP DATA=devinf
.DC TEMP -55 125 10 SWEEP DATA=devinf
.DATA devinf width length thresh cap
+ 50u 30u 1.2v 1.2pf
+ 25u 15u 1.0v 0.8pf
+ 5u 2u 0.7v 0.6pf
.ENDDATA
再上例中，將分別利用給出的三組參數對電路進行瞬態、交流、直流掃描。
.ALTER
該語句用來對電路進行不同參數下的模擬，這些參數包括：電路拓撲結構、模型、庫元件、參數值、選項、源激勵、變量等。
Examples:
.PARAM A=4ns B=5ns