nginx系列（nginx啟動、關閉控制 windows）

入標題中這是在windows環境下面操作的：

下面的文件代碼：

@echo off
rem 當前bat的作用
 
echo ==================begin========================
 
cls 
SET NGINX_PATH=D:
SET NGINX_DIR=D:\nginx\
color 0a 
TITLE Nginx 管理程序 Power By Ants (http://leleroyn.cnblogs.com)
 
CLS 
 
ECHO. 
ECHO. * * Nginx 管理程序 Power By Ants (http://leleroyn.cnblogs.com)  *  
ECHO. * update by 鑫哥 2013-03-13 *  
ECHO. 
 
:MENU 
 
ECHO. * nginx 進程list *  
tasklist|findstr /i "nginx.exe"
 
ECHO. 
    ECHO.  [1] 啟動Nginx  
    ECHO.  [2] 關閉Nginx  
    ECHO.  [3] 重啟Nginx  
    ECHO.  [4] 退 出 
ECHO. 
 
ECHO.請輸入選擇項目的序號:
set /p ID=
    IF "%id%"=="1" GOTO start 
    IF "%id%"=="2" GOTO stop 
    IF "%id%"=="3" GOTO restart 
    IF "%id%"=="4" EXIT
PAUSE 
 
:start 
    call :startNginx
    GOTO MENU
 
:stop 
    call :shutdownNginx
    GOTO MENU
 
:restart 
    call :shutdownNginx
    call :startNginx
    GOTO MENU
 
:shutdownNginx
    ECHO. 
    ECHO.關閉Nginx...... 
    taskkill /F /IM nginx.exe > nul
    ECHO.OK,關閉所有nginx 進程
    goto :eof
 
:startNginx
    ECHO. 
    ECHO.啟動Nginx...... 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" ECHO "%NGINX_DIR%nginx.exe"不存在 
 
    %NGINX_PATH% 
 
    cd "%NGINX_DIR%" 
 
    IF EXIST "%NGINX_DIR%nginx.exe" (
        echo "start '' nginx.exe"
        start "" nginx.exe
    )
    ECHO.OK
    goto :eof

保存后文件格式改成bat文件即可。

 

簡單易用