QT\LINUX中.pro文件的寫法

在QT中，有一個工具qmake可以生成一個makefile文件，它是由.pro文件生成而來的，.pro文件的寫法如下：

1. 注釋
從“#”開始，到這一行結束。

2. 指定源文件
SOURCES = *.cpp

對於多源文件，可用空格分開，如：SOURCES = 1.cpp 2.cpp 3.cpp
或者每一個文件可以被列在一個分開的行里面，通過反斜線另起一行，就像這樣:

SOURCES = hello.cpp \
main.cpp
一個更冗長的方法是單獨地列出每一個文件，就像這樣：

    SOURCES += hello.cpp
SOURCES += main.cpp

這種方法中使用“+=”比“=”更安全，因為它只是向已有的列表中添加新的文件，而不是替換整個列表。

3. 指定頭文件
HEADERS = hello.h或者HEADERS += hello.h

列出源文件的任何一個方法對頭文件也都適用。

4. 配置信息
CONFIG用來告訴qmake關於應用程序的配置信息。

    CONFIG += qt warn_on release

在這里使用“+=”，是因為我們添加我們的配置選項到任何一個已經存在中。這樣做比使用“=”那樣替換已經指定的所有選項是更安全的。
A> qt部分告訴qmake這個應用程序是使用Qt來連編的。這也就是說qmake在連接和為編譯添加所需的包含路徑的時候會考慮到Qt庫的。
B> warn_on部分告訴qmake要把編譯器設置為輸出警告信息的。
C> release部分告訴qmake應用程序必須被連編為一個發布的應用程序。在開發過程中，程序員也可以使用debug來替換release

5. 指定目標文件名
TARGET = filename

如果不設置該項目，目標名會被自動設置為跟項目文件一樣的名稱

6. 添加界面文件(ui)
INTERFACES = filename.ui

7. 平台相關性處理
我們在這里需要做的是根據qmake所運行的平台來使用相應的作用域來進行處理。為Windows平台添加的依賴平台的文件的簡單的作用域看起來就像這樣：

win32 {
SOURCES += hello_win.cpp
}

所以如果qmake運行在Windows上的時候，它就會把hello_win.cpp添加到源文件列表中。如果qmake運行在其它平台上的時候，它會很簡單地把這部分忽略。

8. 如果一個文件不存在，停止qmake
如 果某一個文件不存在的時候，你也許不想生成一個Makefile。我們可以通過使用exists()函數來檢查一個文件是否存在。我們可以通過使用 error()函數把正在運行的qmake停下來。這和作用域的工作方式一樣。只要很簡單地用這個函數來替換作用域條件。對main.cpp文件的檢查就 像這樣：

!exists( main.cpp ) {
error( "No main.cpp file found" )
}

“!”用來否定這個測試，比如，如果文件存在，exists( main.cpp )是真，如果文件不存在，!exists( main.cpp )是真。

9. 檢查多於一個的條件
假 設你使用Windows並且當你在命令行運行你的應用程序的時候你想能夠看到qDebug()語句。除非你在連編你的程序的時候使用console設置， 你不會看到輸出。我們可以很容易地把console添加到CONFIG行中，這樣在Windows下，Makefile就會有這個設置。但是如果告訴你我 們只是想在當我們的應用程序運行在Windows下並且當debug已經在CONFIG行中的時候，添加console。這需要兩個嵌套的作用域；只要生 成一個作用域，然后在它里面再生成另一個。把設置放在最里面的作用域里，就像這樣：

win32 {
debug {
CONFIG += console
}
}

嵌套的作用域可以使用冒號連接起來，像這樣：

win32:debug {
CONFIG += console
}

10. 摸板
模板變量告訴qmake為這個應用程序生成哪種makefile。下面是可供使用的選擇：

A> app - 建立一個應用程序的makefile。這是默認值，所以如果模板沒有被指定，這個將被使用。
B> lib - 建立一個庫的makefile。
C> vcapp - 建立一個應用程序的Visual Studio項目文件。
D> vclib - 建立一個庫的Visual Studio項目文件。
E> subdirs - 這是一個特殊的模板，它可以創建一個能夠進入特定目錄並且為一個項目文件生成makefile並且為它調用make的makefile。

11. 生成Makefile
當你已經創建好你的項目文件，生成Makefile就很容易了，你所要做的就是先到你所生成的項目文件那里然后輸入：

Makefile可以像這樣由“.pro”文件生成：

    qmake -o Makefile hello.pro

對於Visual Studio的用戶，qmake也可以生成“.dsp”文件，例如：

    

 qmake -t vcapp -o hello.dsp hello.pro

 

• app - 建立一個應用程序的makefile。這是默認值，所以如果模板沒有被指定，這個將被使用。

• lib - 建立一個庫的makefile。

• vcapp - 建立一個應用程序的Visual Studio項目文件。

• vclib - 建立一個庫的Visual Studio項目文件。

• subdirs - 這是一個特殊的模板，它可以創建一個能夠進入特定目錄並且為一個項目文件生成makefile並且為它調用make的makefile。

“app”模板

 

“app”模板告訴qmake為建立一個應用程序生成一個makefile。當使用這個模板時，下面這些qmake系 統變量是被承認的。你應該在你的.pro文件中使用它們來為你的應用程序指定特定信息。

 

• HEADERS - 應用程序中的所有頭文件的列表。

• SOURCES - 應用程序中的所有源文件的列表。

• FORMS - 應用程序中的所有.ui文件（由Qt設計器生成）的列表。

• LEXSOURCES - 應用程序中的所有lex源文件的列表。

• YACCSOURCES - 應用程序中的所有yacc源文件的列表。

• TARGET - 可執行應用程序的名稱。默認值為項目文件的名稱。（如果需要擴展名，會被自動加上。）

• DESTDIR - 放置可執行程序目標的目錄。

• DEFINES - 應用程序所需的額外的預處理程序定義的列表。

• INCLUDEPATH - 應用程序所需的額外的包含路徑的列表。

• DEPENDPATH - 應用程序所依賴的搜索路徑。

• VPATH - 尋找補充文件的搜索路徑。

• DEF_FILE - 只有Windows需要：應用程序所要連接的.def文件。

• RC_FILE - 只有Windows需要：應用程序的資源文件。

• RES_FILE - 只有Windows需要：應用程序所要連接的資源文件。

 

 

 

CONFIG變量

 

配置變量指定了編譯器所要使用的選項和所需要被連接的庫。配置變量中可以添加任何東西，但只有下面這些選項可以被qmake識別。

 

下面這些選項控制着使用哪些編譯器標志：

 

• release - 應用程序將以release模式連編。如果“debug”被指定，它將被忽略。

• debug - 應用程序將以debug模式連編。

• warn_on - 編譯器會輸出盡可能多的警告信息。如果“warn_off”被指定，它將被忽略。

• warn_off - 編譯器會輸出盡可能少的警告信息。

 

下面這些選項定義了所要連編的庫/應用程序的類型：

 

• qt - 應用程序是一個Qt應用程序，並且Qt庫將會被連接。

• thread - 應用程序是一個多線程應用程序。

• x11 - 應用程序是一個X11應用程序或庫。

• windows - 只用於“app”模板：應用程序是一個Windows下的窗口應用程序。

• console - 只用於“app”模板：應用程序是一個Windows下的控制台應用程序。

• dll - 只用於“lib”模板：庫是一個共享庫（dll）。

• staticlib - 只用於“lib”模板：庫是一個靜態庫。

• plugin - 只用於“lib”模板：庫是一個插件，這將會使dll選項生效。

 

例如，如果你的應用程序使用Qt庫，並且你想把它連編為一個可調試的多線程的應用程序，你的項目文件應該會有下面這行：

 

CONFIG += qt thread debug

 

注意，你必須使用“+=”，不要使用“=”，否則qmake就不能正確使用連編Qt的設置了，比如沒法獲得所編譯的Qt庫的類型 了。

qmake高級概念

操作符

• “=”操作符      分配一個值給一個變量

• “+=”操作符     向一個變量的值的列表中添加一個值

• “-=”操作 符      從一個變量的值的列表中移去一個值

• “*=”操作符      僅僅在一個值不存在於一個變量的值的列表中的時候，把它添加進去

• “~=”操作符      替換任何與指定的值的正則表達式匹配的任何值 DEFINES ~= s/QT_[DT].+/QT

作用域

win32:thread {

DEFINES += QT_THREAD_SUPPORT
} else:debug {
DEFINES += QT_NOTHREAD_DEBUG
} else {
warning("Unknown configuration")
}
}

 

變量

 

到目前為止我們遇到的變量都是系統變量，比如DEFINES、SOURCES和HEADERS。 你也可以為你自己創建自己的變量，這樣你就可以在作用域中使用它們了。創建自己的變量很容易，只要命名它並且分配一些東西給它。比如：

 

MY_VARIABLE = value

 

你也可以通過在其它任何一個變量的變量名前加$$來把這個變量的值分配給當前的變量。例如：

 

MY_DEFINES = $$DEFINES

MY_DEFINES = $${DEFINES}

第二種方法允許你把一個變量和其它變量連接起來，而不用使用空格。qmake將允許一個變量包含任何東西（包 括$(VALUE)，可以直接在makefile中直接放置，並且允許它適當地擴張，通常是一個環境變量）。無論如何，如果你需要立即設置一個環境變量， 然后你就可以使用$$()方法。比如：

 

MY_DEFINES = $$(ENV_DEFINES)

 

這將會設置MY_DEFINES為環境變量ENV_DEFINES傳遞給.pro文件地值。另外你可以在替換的變量里調用內置函數。這些函數（不會 和下一節中列舉的測試函數混淆）列出如下：

 

join( variablename, glue, before, after )

 

這將會在variablename的各個值中間加入glue。如果這個變量的值為非空，那么就會在值的前面加一個前綴before和 一個后綴after。只有variablename是必須的字段，其它默認情況下為空串。如果你需要在glue、before或 者after中使用空格的話，你必須提供它們。

 

member( variablename, position )

 

這將會放置variablename的列表中的position位置的值。如果variablename不 夠長，這將會返回一個空串。variablename是唯一必須的字段，如果沒有指定位置，則默認為列表中的第一個值。

 

find( variablename, substr )

 

這將會放置variablename中所有匹配substr的值。substr也可以是正 則表達式，而因此將被匹配。

 

MY_VAR = one two three four
MY_VAR2 = $$join(MY_VAR, " -L", -L) -Lfive
MY_VAR3 = $$member(MY_VAR, 2) $$find(MY_VAR, t.*)

 

MY_VAR2將會包含“-Lone -Ltwo -Lthree -Lfour -Lfive”，並且MYVAR3將會包含“three two three”。

 

system( program_and_args )

 

這將會返回程序執行在標准輸出/標准錯誤輸出的內容，並且正像平時所期待地分析它。比如你可以使用這個來詢問有關平台的信息。

 

UNAME = $$system(uname -s)
contains( UNAME, [lL]inux ):message( This looks like Linux ($$UNAME) to me )

 

測試函數

 

qmake提供了可以簡單執行，但強大測試的內置函數。這些測試也可以用在作用域中（就像上面一樣），在一些情況下，忽略它的測 試值，它自己使用測試函數是很有用的。

 

contains( variablename, value )

 

如果value存在於一個被叫做variablename的變量的值的列表中，那么這個作用域中的設置將會被 處理。例如：

 

contains( CONFIG, thread ) {
DEFINES += QT_THREAD_SUPPORT
}

 

如果thread存在於CONFIG變量的值的列表中時，那么QT_THREAD_SUPPORT將會被加入 到DEFINES變量的值的列表中。

 

count( variablename, number )

 

如果number與一個被叫做variablename的變量的值的數量一致，那么這個作用域中的設置將會被 處理。例如：

 

count( DEFINES, 5 ) {
CONFIG += debug
}

 

error( string )

 

這個函數輸出所給定的字符串，然后會使qmake退出。例如：

 

error( "An error has occured" )

 

文本“An error has occured”將會被顯示在控制台上並且qmake將會退出。

 

exists( filename )

 

如果指定文件存在，那么這個作用域中的設置將會被處理。例如：

 

exists( /local/qt/qmake/main.cpp ) {
SOURCES += main.cpp
}

 

如果/local/qt/qmake/main.cpp存在，那么main.cpp將會被添加到源文件列表中。

 

注意可以不用考慮平台使用“/”作為目錄的分隔符。

 

include( filename )

 

項目文件在這一點時包含這個文件名的內容，所以指定文件中的任何設置都將會被處理。例如：

 

include( myotherapp.pro )

 

myotherapp.pro項目文件中的任何設置現在都會被處理。

 

isEmpty( variablename )

 

這和使用count( variablename, 0 )是一樣的。如果叫做variablename的變量沒有任何元素，那 么這個作用域中的設置將會被處理。例如：

 

isEmpty( CONFIG ) {
CONFIG += qt warn_on debug
}

 

message( string )

 

這個函數只是簡單地在控制台上輸出消息。

 

message( "This is a message" )

 

文本“This is a message”被輸出到控制台上並且對於項目文件的處理將會繼續進行。

 

system( command )

 

特定指令被執行並且如果它返回一個1的退出值，那么這個作用域中的設置將會被處理。例如：

 

system( ls /bin ) {
SOURCES += bin/main.cpp
HEADERS += bin/main.h
}

 

所以如果命令ls /bin返回1，那么bin/main.cpp將被添加到源文件列表中並且bin/main.h將 被添加到頭文件列表中。

 

infile( filename, var, val )

 

如果filename文件（當它被qmake自己解析時）包含一個值為val的變量var， 那么這個函數將會返回成功。你也可以不傳遞第三個參數（val），這時函數將只測試文件中是否分配有這樣一個變量var。

以下為我的一個項目舉例
# 項目目標：為一個庫文件

TEMPLATE = lib
# 編譯項目文件所需頭文件的路徑
INCLUDEPATH += ../common .
# 目標文件路徑
DESTDIR=../lib
# 條件依賴：Unix平台上 定義本想目的 UI目錄， MOC目錄， 目的目錄
unix {
UI_DIR = ../.ui
MOC_DIR = ../.moc
OBJECTS_DIR = ../.obj
}
# 本項目配置：
CONFIG += qt warn_on release thread

# Input 頭文件 ，源文件
HEADERS += COMControllerThread.h \
DecodeSMS.h \
monitor_common.h \
monitor_interface.h \
MonitorThread.h \
UserEvent.h \
MyCOM.h \
MySMS.h \
MyTagHandle.h \
SMSParseThread.h \
tag_dict.h
SOURCES += COMControllerThread.cpp \
DecodeSMS.cpp \
monitor_common.cpp \
monitor_interface.cpp \
MonitorThread.cpp \
MyCOM.cpp \
MySMS.cpp \
MyTagHandle.cpp \
SMSParseThread.cpp \
tag_dict.cpp

注：

 

• qmake -project 可以生成pro文件（可以根據項目需要，編輯改文件）
• qmake 可以生成Makefile文件
• make 編譯

 

• 使用qmake -project時，會把本目錄及其子目錄內所有.cpp .h文件加入到項目輸入文件中，使用是注意移去其他無用的文件。
• qmake生成的Makefile文件，可以根據需要做相應修改

 

 

文章來源於：http://www.diybl.com/course/6_system/linux/Linuxjs/20071114/86141.html