ABAP 動態生成內表的幾種方法(Several Methods of Dynamic Internal Table Creation)
最近要寫個程序，既有更新的，也有刪除的，需要涉及到很多系統表，如果一個表一個表進行更新或者刪除太慢了，於是就想通過創建動態內表來實現這些功能，在網上找了一些資料，經過多次嘗試，終於測試成功了。網上講述的創建動態內表的方法大致有兩種。我做了一下測試，源代碼附后。在這里提醒大家一點，在做動態更新程序的時候，要注意兩點：
1.使用modify (p_tabname) from <dyn_wa>. 的時候，一定要確定要更新的字段是不是系統表的關鍵字段，如果是關鍵字段的話，需要先刪除這條記錄，delete (p_tabname) from <dyn_wa>.再進行modify,因為modify進行更新的時候如果不存在就新增，這點一定要注意。
2.如果使用UPDATE進行更新，對於非主鍵字段的改變還是可以的，但是對於主鍵字段，只能用MODIFY了。直接對SAP數據做UPDATE和MODIFY是很危險的，不到萬不得已，最好不要做這些操作。如果萬一出問題，會很嚴重的。這里就不用更新和刪除程序作為測試程序了，直接做一個動態內表ALV顯示的測試程序，道理和更新與刪除差不多，希望對有這方面需求的朋友有所幫助！
3.最近從同事程序中發現另一種創建動態內表的簡便方法，附3中為測試代碼。覺得這個方法更簡單些……
附1：
REPORT ZCL_TEST026.
TYPE-POOLS:abap.
PARAMETERS p_name TYPE tabname.
DATA lt_table TYPE TABLE OF dfies. "字段結構表
DATA ls_table TYPE dfies.
DATA lr_struc TYPE REF TO cl_abap_structdescr.
DATA lr_table TYPE REF TO cl_abap_tabledescr.
DATA lr_type TYPE REF TO cl_abap_typedescr.
DATA lr_data TYPE REF TO cl_abap_datadescr.
DATA lt_comp TYPE abap_component_tab.
DATA ls_comp LIKE LINE OF lt_comp.
DATA dyn_wa TYPE REF TO data.
DATA dyn_table TYPE REF TO data.
DATA l_string TYPE string.
FIELD-SYMBOLS: <dyn_table> TYPE STANDARD TABLE,
<dyn_wa> TYPE ANY.
*1.獲取表中的字段結構
CALL FUNCTION 'DDIF_NAMETAB_GET'
EXPORTING
tabname = p_name
TABLES
dfies_tab = lt_table
EXCEPTIONS
not_found = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
LOOP AT lt_table INTO ls_table.
CONCATENATE ls_table-tabname '-' ls_table-fieldname INTO l_string.
ls_comp-name = ls_table-fieldname.
*讀取字段類型
CALL METHOD cl_abap_datadescr=>describe_by_name
EXPORTING
p_name = l_string
RECEIVING
p_descr_ref = lr_type
EXCEPTIONS
type_not_found = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ls_comp-type ?= lr_type.
APPEND ls_comp TO lt_comp.
CLEAR ls_comp.
ENDLOOP.
*根據字段目錄創建動態結構類型
CALL METHOD cl_abap_structdescr=>create
EXPORTING
p_components = lt_comp
RECEIVING
p_result = lr_struc.
*根據動態結構創建動態內表類型
CALL METHOD cl_abap_tabledescr=>create
EXPORTING
p_line_type = lr_struc
RECEIVING
p_result = lr_table.
*參照動態結構類型和動態內表類型創建內表與工作區
CREATE DATA dyn_wa TYPE HANDLE lr_struc.
CREATE DATA dyn_table TYPE HANDLE lr_table.
*指定內表與工作區到字段符號
ASSIGN dyn_wa->* TO <dyn_wa>.
ASSIGN dyn_table->* TO <dyn_table>.
*從動態表中取數到動態內表中
SELECT * INTO CORRESPONDING FIELDS OF TABLE <dyn_table> UP TO 100
ROWS FROM (p_name).
*顯示內表中的數據
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_structure_name = p_name
TABLES
t_outtab = <dyn_table>
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
附2：
REPORT ZCL_TEST027.
TYPE-POOLS:abap.
PARAMETERS p_name TYPE tabname.
DATA: d_ref TYPE REF TO data,
lt_alv_cat TYPE TABLE OF lvc_s_fcat,
ls_alv_cat LIKE LINE OF lt_alv_cat.
DATA: lt_table LIKE TABLE OF dntab.
DATA: ls_table TYPE dntab.
FIELD-SYMBOLS : <dyn_table> TYPE table,
<dyn_wa> TYPE ANY,
<dyn_field> TYPE ANY.
*取出表結構的字段目錄
CALL FUNCTION 'NAMETAB_GET'
EXPORTING
langu = sy-langu
tabname = p_name
TABLES
nametab = lt_table
EXCEPTIONS
no_texts_found = 1.
*根據取出的字段目錄生成參考字段目錄
LOOP AT lt_table INTO ls_table.
ls_alv_cat-fieldname = ls_table-fieldname.
ls_alv_cat-ref_table = p_name.
ls_alv_cat-ref_field = ls_table-fieldname.
APPEND ls_alv_cat TO lt_alv_cat.
CLEAR ls_alv_cat.
ENDLOOP.
*內表創建
CALL METHOD cl_alv_table_create=>create_dynamic_table
EXPORTING
it_fieldcatalog = lt_alv_cat
IMPORTING
ep_table = d_ref.
*指定生成的內表到字段符號
ASSIGN d_ref->* TO <dyn_table>.
*從動態表中取數到動態內表中
SELECT * INTO CORRESPONDING FIELDS OF TABLE <dyn_table> UP TO 100
ROWS FROM (p_name).
*顯示內表中的數據
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_structure_name = p_name
TABLES
t_outtab = <dyn_table>
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
附3：
REPORT ZCL_TEST028.
PARAMETERS p_name TYPE tabname.
DATA: dyn_table TYPE REF TO data.
DATA: dyn_wa TYPE REF TO data.
FIELD-SYMBOLS: <dyn_table> TYPE table,
<dyn_wa> TYPE ANY.
*創建動態表結構
CREATE DATA dyn_table TYPE TABLE OF (p_name).
*創建動態內表
ASSIGN dyn_table->* TO <dyn_table>.
*創建動態工作區結構
CREATE DATA dyn_wa LIKE LINE OF <dyn_table>.
*創建動態工作區
ASSIGN dyn_wa->* TO <dyn_wa>.
*從動態表中取數到動態內表中
SELECT * INTO CORRESPONDING FIELDS OF TABLE <dyn_table> UP TO 100
ROWS FROM (p_name).
*對取出數據進行處理
LOOP AT <dyn_table> assigning <dyn_wa>.
"內表數據處理
ENDLOOP.
*顯示內表中的數據
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_structure_name = p_name
TABLES
t_outtab = <dyn_table>
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
轉自：http://www.cnblogs.com/clsoho/archive/2010/07/23/1783851.html
ABAP動態內表使用的例子
*&---------------------------------------------------------------------*
*& Report ZLEIY_ABAP_TEST
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
REPORT ZLEIY_ABAP_TEST.
FIELD-SYMBOLS: <dyn_table> TYPE STANDARD TABLE,
<dyn_wa>,
<dyn_field>.
DATA: dy_table TYPE REF TO data,
dy_line TYPE REF TO data,
it_structure TYPE lvc_t_fcat,
wa_structure TYPE lvc_s_fcat.
START-OF-SELECTION.
PERFORM create_structure. " 定義內表的結構
PERFORM create_dynamic_table. " 按照定義的內表結構，產生一個內表
PERFORM write_data_to_dyntable. " 向動態內表中寫數
PERFORM output_dyntable_data. " 從動態內表中取數，並寫到屏幕
*&---------------------------------------------------------------------*
*& Form create_structure
*&---------------------------------------------------------------------*
FORM create_structure .
wa_structure-fieldname = 'COL1'. " 第一列列名
wa_structure-col_pos = 1. " 表示第一列 --- 可心省略，默認情況下，第一行對應到生產內表的第一列，如果指定，則按指定的列順序生成內表
wa_structure-inttype = 'C'. " 數據類型
wa_structure-intlen = 6. " 長度
APPEND wa_structure TO it_structure.
wa_structure-fieldname = 'COL2'. " 第二列列名
wa_structure-col_pos = 2. " 表示第二列--- 可心省略，默認情況下，第一行對應到生產內表的第一列，如果指定，則按指定的列順序生成內表
wa_structure-inttype = 'C'. " 數據類型
wa_structure-intlen = 6. " 長度
APPEND wa_structure TO it_structure.
wa_structure-fieldname = 'COL3'. " 第三列名
wa_structure-col_pos = 3. " 表示第三列 --- 可心省略，默認情況下，第一行對應到生產內表的第一列，如果指定，則按指定的列順序生成內表
wa_structure-inttype = 'C'. " 數據類型
wa_structure-intlen = 6. " 長度
APPEND wa_structure TO it_structure.
ENDFORM. " create_structure
*&---------------------------------------------------------------------*
*& Form create_dynamic_table
*&---------------------------------------------------------------------*
FORM create_dynamic_table .
CALL METHOD cl_alv_table_create=>create_dynamic_table
EXPORTING
it_fieldcatalog = it_structure
IMPORTING
ep_table = dy_table.
ASSIGN dy_table->* TO <dyn_table>. " 用表類型指針 <dyn_table> 指向 數據對象的內容.
ENDFORM. " create_dynamic_table
*&---------------------------------------------------------------------*
*& Form write_data_to_dyntable
*&---------------------------------------------------------------------*
FORM write_data_to_dyntable .
DATA:wa_new_line TYPE REF TO data.
DATA:i TYPE n.
DATA:j TYPE n.
CREATE DATA wa_new_line LIKE LINE OF <dyn_table>. " 建立一個與動態內表結構相同的數據對象，且數據對象為是一個結構
ASSIGN wa_new_line->* TO <dyn_wa>.
" 用<dyn_wa>指針指向該結構
DO 3 TIMES.
i = i + 1.
CLEAR j.
LOOP AT it_structure INTO wa_structure.
j = j + 1.
ASSIGN COMPONENT wa_structure-fieldname OF STRUCTURE <dyn_wa> TO <dyn_field>. " 用指針 <dyn_field>指向工作區<dyn_wa>中的一個字段，字段名為wa_structure-fieldname.
CONCATENATE i j INTO <dyn_field>. " 給指針指向的字段賦值
ENDLOOP.
APPEND <dyn_wa> TO <dyn_table>.
ENDDO.
ENDFORM. " write_data_to_dyntable
*&---------------------------------------------------------------------*
*& Form output_dyntable_data
*&---------------------------------------------------------------------*
FORM output_dyntable_data .
LOOP AT it_structure INTO wa_structure.
WRITE: wa_structure-fieldname(5).
ENDLOOP.
LOOP AT <dyn_table> INTO <dyn_wa>.
WRITE: / .
LOOP AT it_structure INTO wa_structure.
ASSIGN COMPONENT wa_structure-fieldname OF STRUCTURE <dyn_wa> TO <dyn_field>. " 用指針 <dyn_field>指向工作區<dyn_wa>中的一個字段，字段名為wa_structure-fieldname.
WRITE: <dyn_field>.
ENDLOOP.
ENDLOOP.
ENDFORM.
----output
