Delphi ListView快速操作通用實現

眾所周知，Delphi ListView類直接進行Add、Update、Delete操作的速度是比較慢的，尤其是當數據量較大時，比如數據量達到5000、10000、50000時，速度真是可以說是“慢得驚人”。其實快速操作的方法非常簡單，就當大家都知道了。在本人的工作中，很多項目都用到ListView，並且對速度的響應要求比較高，於是發生了快速操作ListView的代碼散布於多個項目大量模塊中的問題，並且，當界面層數據顯示要求發生改變時，自然發生“重復性代碼的通用問題”。考慮到對以前版本的兼容性問題，也一直沒有引用第三方的成熟組件。鑒於：“程序中的重復代碼最易引發問題，必須消除”的實踐經驗，自己設計了一個比較通用的解決此類問題的類結構。當然，遠不是什么“通用框架”了(眼下市面上很多人喜歡把自己做的無論什么東西通稱為框架)。在采用此結構的項目中，很容易實現MVC模式，達到業務邏輯與界面顯示分離的低級的、基礎的要求。

Delphi ListView快速操作通用實現

作者：成曉旭

眾所周知，Delphi ListView類直接進行Add、Update、Delete操作的速度是比較慢的，尤其是當數據量較大時，比如數據量達到5000、10000、50000時，速度真是可以說是“慢得驚人”。其實快速操作的方法非常簡單，就當大家都知道了。在本人的工作中，很多項目都用到ListView，並且對速度的響應要求比較高，於是發生了快速操作ListView的代碼散布於多個項目大量模塊中的問題，並且，當界面層數據顯示要求發生改變時，自然發生“重復性代碼的通用問題”。考慮到對以前版本的兼容性問題，也一直沒有引用第三方的成熟組件。鑒於：“程序中的重復代碼最易引發問題，必須消除”的實踐經驗，自己設計了一個比較通用的解決此類問題的類結構。當然，遠不是什么“通用框架”了(眼下市面上很多人喜歡把自己做的無論什么東西通稱為框架)。在采用此結構的項目中，很容易實現MVC模式，達到業務邏輯與界面顯示分離的低級的、基礎的要求。

(因為，目前CSDN的軟件上傳功能不可用，我只有將部分代碼片斷放在文檔中，有需要完整源碼者，請留言)

類層次結構：

ListView基礎操作封裝在LVControler包中，核心的類是TCXXLVControler：

 (說明：LVControler類是被封裝通用類結構內，外部用戶是不需要了解和訪問的，所以不作介紹。)

傳統的ListView操作基類是TLVCommonClass，如果想用傳統的方法增、刪、改ListView中的數據，可以直接從此類繼承。

 源碼如下：

 

具體的一個從此類繼承下來的用於Socket界面顯示的TLVSocket的類Overvivw如下：

源碼如下：

 

快速的ListView操作基類是TLVQuickClass，如果想用快速方法增、刪、改ListView中的數據，可以直接從此類繼承。

主要方法：(可以看到，里面沒有真正的Public方法，子類也僅需實現兩個Protected的virtual方法)

源碼如下：

 

此類中，要求每個具體應用的子類必須實現的方法僅有兩個：CheckFound()：根據具體應用檢測的數據是否已經存在；ProcOnDataDetail()：客戶端ListView的OnData()事件的數據處理回調方法。下面是幾個具體實現的子類的OverView：

具體的一個從此類繼承下來的用於Socket界面顯示的TLVQuickSocket的類Overvivw如下：

         可以看出：子類實現了兩個抽象的虛方法，其它的方法，都是根據業務需要，類用戶自行增加的。

       源碼如下：

      

//------------------------------------------------------------------------------

//

//      產品名稱:   成曉旭的個人軟件Delphi源碼庫

//      產品版本:   CXXSoft delphi code source lib 1.0

//      模塊名稱:   Delphi之ListView顯示控制類---應用層:Soft socket類定義單元

//      模塊描述:

//      單元文件:   unLVSoftSocket.pas-->unLVQuickSocket.pas

//      開發作者:   成曉旭

//      備注:       任何人使用此文件時,請保留此段自述文件,謝謝!

//      開發時間:   2005-09-26

//

//      修改歷史:   2006-06-16

//      修改描述:   增加通過TList來高速增加、更新、刪除數據

//                  先用吧,以后再優化和完善

//      修改歷史:   2006-07-10

//      修改描述:   成功地將ListView的OnData事件的List對象移入此類中

//      修改歷史:   2006-07-11

//      修改描述:   重大重構:將此類分成兩個類:TLVSoftSocket-->TLVSoftSocket和TLVQuickSocket

//                  以遵循SRP原則  

//------------------------------------------------------------------------------

unit unLVQuickSocket;

interface

uses

  ComCtrls,Classes,SysUtils,Windows,

  unLVQuickClass,unLVDefine;

type

  TLVQuickSocket = class(TLVQuickClass)

  private

  protected

    class function  CheckFound(const pData:Pointer;const aKey:variant):boolean;override;

    class procedure ProcOnDataDetail(const pData:Pointer;var Item: TListItem);override;

  public

    constructor Create();

    destructor  Destroy();override;

    procedure InitListView(var lvTemp:TListView);

    //快速方法

    //暫時這樣增加,以后在重構到基類中

    procedure AddToLVSocketQuick(const aSocketStatus:TSocketStatusInfo;var lvTemp:TListView);

    procedure UpdateLVSocketQuick(const aUniqueID:integer;const aSocketStatus:TSocketStatusInfo;var lvTemp:TListView);

    procedure DeleteLVSocketQuick(const aUniqueID:integer;const aSocketStatus:TSocketStatusInfo;var lvTemp:TListView);

    procedure DeleteAllLVSocket(var lvTemp:TListView);

    procedure OnDataEvent(Item: TListItem);

    function  GetDataCount():integer;

  end;

implementation

...{ TLVQuickSocket }

procedure TLVQuickSocket.AddToLVSocketQuick(

  const aSocketStatus: TSocketStatusInfo;var lvTemp:TListView);

begin

  AddItemDataToListView(@aSocketStatus,sizeof(aSocketStatus),lvTemp);

end;

class function TLVQuickSocket.CheckFound(const pData: Pointer;

  const aKey: variant): boolean;

var

  p:^TSocketStatusInfo;

begin

  p := pData;

  Result := (p.UniqueID = aKey);

end;

constructor TLVQuickSocket.Create;

begin

  inherited Create();

end;

procedure TLVQuickSocket.DeleteAllLVSocket(var lvTemp: TListView);

begin

  DeleteAllListView(lvTemp);

end;

procedure TLVQuickSocket.DeleteLVSocketQuick(const aUniqueID:integer;

  const aSocketStatus: TSocketStatusInfo;var lvTemp:TListView);

begin

  DeleteItemDataToListView(aUniqueID,@aSocketStatus,sizeof(aSocketStatus),lvTemp);

end;

destructor TLVQuickSocket.Destroy;

begin

  inherited Destroy;

end;

function TLVQuickSocket.GetDataCount(): integer;

begin

  Result := Self.GetLVListCount();

end;

procedure TLVQuickSocket.InitListView(var lvTemp: TListView);

begin

  InitListViewColumns(SocketStrBuffer,SocketWidthBuffer,lvTemp);

end;

procedure TLVQuickSocket.OnDataEvent(Item: TListItem);

begin

  Self.OnDataToListView(Item);

end;

class procedure TLVQuickSocket.ProcOnDataDetail(const pData: Pointer;var Item: TListItem);

var

  pSocket:^TSocketStatusInfo;

begin

  //這兩個有什么不同?

  //CopyMemory(pSocket,pData,sizeof(TSocketStatusInfo));

  pSocket := pData;

  Item.Caption := IntToStr(pSocket.GroupID);

  Item.SubItems.Add(IntToStr(pSocket.UniqueID));

  Item.SubItems.Add(pSocket.IPAddress);

  Item.SubItems.Add(pSocket.SubItemName);

  Item.SubItems.Add(pSocket.LoginTime);

  Item.SubItems.Add(pSocket.SendNumber);

  Item.SubItems.Add(pSocket.RecNumber);

  Item.SubItems.Add(pSocket.Remark);

end;

procedure TLVQuickSocket.UpdateLVSocketQuick(const aUniqueID:integer;

  const aSocketStatus: TSocketStatusInfo;var lvTemp:TListView);

begin

  UpdateItemDataToListView(aUniqueID,@aSocketStatus,sizeof(aSocketStatus),lvTemp);

end;

end.

 

 

小結：

應用此類結構實現ListView快速數據操作的優勢：

<!--[if !supportLists]-->1、   <!--[endif]-->可以快速實現MVC模式，達到界面顯示與業務邏輯的分離。在Controllor類中，實例化數據顯示子類，調用相應方法即可實現顯示數據的增、刪、改。

<!--[if !supportLists]-->2、   <!--[endif]-->與原始的快速方法相比，封裝了內存數據List，大大簡化了List對象的操作(尤其是當有很多相同或者類似數據要求在不同Form的ListView中顯示時)，並減少了List的創建、數據操作、釋放等操作時發生錯誤的可能性。

<!--[if !supportLists]-->3、   <!--[endif]-->簡化了多個相同、類似數據顯示的控制代碼，針對每個份要顯示的數據及ListView，只需要實例化一個顯示子類，避免了直接應用原始的快速方法時，控制代碼分散在每一個具體Form類中的問題。

<!--[if !supportLists]-->4、   <!--[endif]-->對顯示數據的業務信息份進行了集中，當要求顯示的信息發生變化時，只需在數據顯示子類這一個類中更改即可。

此通用類結構仍有些不足之處，歡迎有興趣的朋友繼續完善：

<!--[if !supportLists]-->１、<!--[endif]-->每個應用層類的外部調用方式非常類似(請參考開發的示例源碼)，表明，有些通用的方法沒有進行更好的抽象。

<!--[if !supportLists]-->２、<!--[endif]-->快速訪問基類對其子類的行為抽象不充分，導致子類的應用層調用代碼非常類似。當初這樣設計的目的是想保持類結構有充分的可擴展性。其實完全可以將基類進行改良：將抽象的虛方法更換成接口，這樣，基類實現的更好的封裝，並且更好地滿足了“向穩定的方向依賴”和“針對接口編程”的設計原則。這樣，應用層還是要實例化一個自己業務需要的類來實現此接口。但Delphi的接口用起來不像是真正的接口，通常要從TInterfacedObject等類繼承，大大限制了類結構層次的演化。(因為在不支持多繼承的語言環境中，如果還想增加更高層次的抽象就不那么容易了)。

<!--[if !supportLists]-->３、<!--[endif]-->當前的版本還沒有提供針對某列進行數據排序的功能。

 

//------------------------------------------------------------------------------

//

//      產品名稱:   成曉旭的個人軟件Delphi源碼庫

//      產品版本:   CXXSoft delphi code source lib 1.0

//      模塊名稱:   Delphi之ListView顯示控制類---外部應用層通用類定義單元

//      模塊描述:   ListView快速操作方法類

//      單元文件:   unLVCommonClass.pas--->unLVQuickClass.pas

//      開發作者:   成曉旭

//      備注:       任何人使用此文件時,請保留此段自述文件,謝謝!

//      開發時間:   2005-09-26

//      修改歷史:   2006-05-31

//      修改描述:   解決GetLVItemOrderByValue()的參數不靈活的問題

//                  並解決Method 'Create' hides virtual method of base type 'TComponent'的問題

//      修改歷史:   2006-06-16

//      修改描述:   增加通過TList來高速增加、更新、刪除數據

//                  先用吧,以后再優化和完善

//      修改歷史:   2006-07-10

//      修改描述:   成功地將ListView的OnData事件的List對象移入此類中,並將其上移到其類

//      修改歷史:   2006-07-11

//      修改描述:   重大重構:將此類分成兩個類:TLVCommonClass-->TLVCommonClass和TLVQuickClass,

//                  以遵循SRP原則

//------------------------------------------------------------------------------

unit unLVQuickClass;

interface

uses

  SysUtils,Classes,ComCtrls,Windows,Variants,

  unLVControler;

  

const

  SpecialItemOrder = -1;

  CSImg_Normal = 0;

  CSImg_Running = 1;

  GetColumnOrder = 0;

type

  TLVQuickClass = class(TInterfacedObject)

  private

    cxxLVC:TCXXLVControler;

    lvDataList: TList;

    //為ListView的Item的Data屬性查詢關鍵數據在TList中的索引號

    class function  GetListDataIndexByKey(const listData:TList;const aKey: variant):integer;

    //快速

    procedure ClearLVDataList();

  protected

    //注意:約定最后一項一定是ImageIndex

    //tmpList:TStringList;

    function  InitListViewColumns(const displayName: array of string;

        const displayWidth: array of integer;

        var lvTemp:TListView):boolean;

    //子類必須實現

    class function  CheckFound(const pData:Pointer;const aKey:variant):boolean;virtual; abstract;

    class procedure ProcOnDataDetail(const pData:Pointer;var Item: TListItem);virtual; abstract;

    //快速方法

    //[注意:新方法中lvList不要求傳遞參數,保留以兼容舊客戶端版本]

    //將pData數據加入List中,實現向ListView增加數據行

    function AddItemDataToListView(const pData:Pointer;const dataNumber:integer;

        var lvTemp:TListView):boolean;

        //; var lvList: TList=nil):boolean;

    //以aKey為關鍵值查找,並用pData數據更新List中滿足條件的內存塊,實現向ListView更新數據行

    function UpdateItemDataToListView(const aKey:variant;const pData:Pointer;const dataNumber:integer;

        var lvTemp:TListView):boolean;

        //; var lvList: TList=nil):boolean;

    //以aKey為關鍵值查找,並用pData數據刪除List中滿足條件的內存塊,實現向ListView刪除數據行

    function DeleteItemDataToListView(const aKey:variant;const pData:Pointer;const dataNumber:integer;

        var lvTemp:TListView):boolean;

        //; var lvList: TList=nil):boolean;

    //刪除List中所有內存區,實現將ListView清空所有數據行

    procedure DeleteAllListView(var lvTemp:TListView);

    //ListVisw的OnData事件處理

    procedure OnDataToListView(var Item: TListItem);

    //ListVisw的OnData事件的List Count

    function  GetLVListCount():integer;

  public

    constructor Create();overload;

    destructor Destroy();override;

  end;

implementation

...{ TLVQuickClass }

function TLVQuickClass.AddItemDataToListView(const pData: Pointer;

  const dataNumber: integer; var lvTemp: TListView):boolean;

  //; var lvList: TList):boolean;

var

  pTemp:Pointer;

begin

  //注意:要影響性能

  //lvTemp.Items.BeginUpdate();

  Result := false;

  if NOT (Assigned(pData) and Assigned(lvTemp) and Assigned(lvDataList)) then Exit;

  //new(pTemp);

  GetMem(pTemp,dataNumber);

  lvTemp.OwnerData := true;

  CopyMemory(pTemp,pData,dataNumber);

  lvDataList.Add(pTemp);

  Result := true;

  //注意:要影響性能

  //lvTemp.Items.Count := lvList.Count;

  //lvTemp.Items.EndUpdate();  

end;

procedure TLVQuickClass.ClearLVDataList();

var

  Loop:integer;

  pTemp:Pointer;

begin

  if NOT (Assigned(lvDataList) and (lvDataList.Count > 0)) then Exit;

  for Loop := 0 to lvDataList.Count - 1 do

  begin

    pTemp := (lvDataList.Items[Loop]);

    if Assigned(pTemp) then

      FreeMem(pTemp);

  end;

end;

constructor TLVQuickClass.Create;

begin

  inherited Create();

  cxxLVC := TCXXLVControler.Create();

  //tmpList := TStringList.Create();

  lvDataList := TList.Create();  

end;

procedure TLVQuickClass.DeleteAllListView(var lvTemp: TListView);

begin

  if NOT (Assigned(lvTemp) and Assigned(lvDataList) and (lvDataList.Count > 0)) then Exit;

  lvTemp.OwnerData := true;

  lvTemp.Items.BeginUpdate();

  while (lvDataList.Count > 0) do

  begin

    Dispose(lvDataList[0]);

    lvDataList.Delete(0);

  end;

  lvTemp.Items.Count := lvDataList.Count;

  lvTemp.Items.EndUpdate();

end;

function TLVQuickClass.DeleteItemDataToListView(const aKey: variant;

  const pData: Pointer; const dataNumber: integer; var lvTemp: TListView):boolean;

  //var lvList: TList): boolean;

var

  colIndex:integer;

begin

  //注意:要影響性能

  //lvTemp.Items.BeginUpdate();

  Result := false;

  if NOT (Assigned(pData) and Assigned(lvTemp) and Assigned(lvDataList) and (lvDataList.Count > 0)) then Exit;

  colIndex := GetListDataIndexByKey(lvDataList,aKey);

  if (colIndex <> SpecialItemOrder) and (colIndex >= 0) and (colIndex <= lvDataList.Count - 1) then

  begin

    Dispose(lvDataList[colIndex]);

    lvDataList.Delete(colIndex);

    Result := true;

  end;

  //注意:要影響性能

  //lvTemp.Items.Count := lvList.Count;

  //lvTemp.Items.EndUpdate();

end;

destructor TLVQuickClass.Destroy;

begin

  ClearLVDataList();

  if Assigned(lvDataList) then

    FreeAndNil(lvDataList);

  if Assigned(cxxLVC) then

    FreeAndNil(cxxLVC);

  //if Assigned(tmpList) then

  //  FreeAndNil(tmpList);

  inherited Destroy;

end;

class function TLVQuickClass.GetListDataIndexByKey(const listData: TList;

  const aKey: variant): integer;

var

  Loop:integer;

begin

  Result := SpecialItemOrder;

  if NOT Assigned(listData) then Exit;

  if listData.Count <= 0 then Exit;

  for Loop := 0 to listData.Count - 1 do

  begin

    if CheckFound(listData[Loop],aKey) then

    begin

      Result := Loop;

      break;

    end;

  end;

end;

function TLVQuickClass.GetLVListCount(): integer;

begin

  Result := 0;

  if Assigned(lvDataList) then

    Result := lvDataList.Count;

end;

function TLVQuickClass.InitListViewColumns(const displayName: array of string;

  const displayWidth: array of integer; var lvTemp: TListView): boolean;

begin

  Result := false;

  if Assigned(cxxLVC) then

  begin

    cxxLVC.InitLVColumns(displayName,displayWidth,lvTemp);

  end;

end;

procedure TLVQuickClass.OnDataToListView(var Item: TListItem);

var

  pTemp:Pointer;

begin

  //以后要移到類中,做成回調

  if NOT Assigned(lvDataList) then Exit;

  if lvDataList.Count <= 0 then Exit;

  if Item.Index > lvDataList.Count then Exit;

  pTemp := lvDataList[Item.Index];

  ProcOnDataDetail(pTemp,Item);

  Item.ImageIndex := 1;

  Item.Data := pTemp;

end;

function TLVQuickClass.UpdateItemDataToListView(const aKey: variant;

  const pData: Pointer; const dataNumber: integer; var lvTemp: TListView):boolean;

  //var lvList: TList):boolean;

var

  colIndex:integer;

begin

  //注意:要影響性能

  //lvTemp.Items.BeginUpdate();

  Result := false;

  if NOT (Assigned(pData) and Assigned(lvTemp) and Assigned(lvDataList) and (lvDataList.Count > 0)) then Exit;

  colIndex := GetListDataIndexByKey(lvDataList,aKey);

  if (colIndex <> SpecialItemOrder) and (colIndex >= 0) and (colIndex <= lvDataList.Count - 1) then

  begin

    CopyMemory(lvDataList[colIndex],pData,dataNumber);

    Result := true;

  end;

  //注意:要影響性能  

  //lvTemp.Items.Count := lvList.Count;

  //lvTemp.Items.EndUpdate();

end;

end.

 

//------------------------------------------------------------------------------

//

//      產品名稱:   成曉旭的個人軟件Delphi源碼庫

//      產品版本:   CXXSoft delphi code source lib 1.0

//      模塊名稱:   Delphi之ListView顯示控制類---應用層:Soft socket類定義單元

//      模塊描述:

//      單元文件:   unLVSoftSocket.pas-->unLVSocket.pas

//      開發作者:   成曉旭

//      備注:       任何人使用此文件時,請保留此段自述文件,謝謝!

//      開發時間:   2005-09-26

//

//      修改歷史:   2006-06-16

//      修改描述:   增加通過TList來高速增加、更新、刪除數據

//                  先用吧,以后再優化和完善

//      修改歷史:   2006-07-10

//      修改描述:   成功地將ListView的OnData事件的List對象移入此類中

//      修改歷史:   2006-07-11

//      修改描述:   重大重構:將此類分成兩個類:TLVSoftSocket-->TLVSocket和TLVQuickClass

//                  以遵循SRP原則  

//------------------------------------------------------------------------------

unit unLVSocket;

interface

uses

  ComCtrls,Classes,SysUtils,Windows,

  unLVCommonClass,unLVDefine;

type

  TLVSocket = class(TLVCommonClass)

  private

    //注意:此方法與順序嚴重藕合

    function  SaveSerialStatusToStringList(const aSocketStatus:TSocketStatusInfo):boolean;    

  protected

    class function  CheckFound(const pData:Pointer;const aKey:variant):boolean;override;

    class procedure ProcOnDataDetail(const pData:Pointer;var Item: TListItem);override;

  public

    constructor Create();

    destructor  Destroy();override;

    procedure InitListView(var lvTemp:TListView);

    //傳統方法

    procedure AddToLVSocket(const aSocketStatus:TSocketStatusInfo;var lvTemp:TListView);

    procedure UpdateLVSocket(const aSocketStatus:TSocketStatusInfo;var lvTemp:TListView);

    procedure DeleteLVSocket(const aSocketStatus:TSocketStatusInfo;var lvTemp:TListView);

  end;

implementation

...{ TLVSocket }

procedure TLVSocket.AddToLVSocket(

  const aSocketStatus: TSocketStatusInfo; var lvTemp: TListView);

begin

  if SaveSerialStatusToStringList(aSocketStatus) then

  begin

    AddDataToListView(tmpList,lvTemp);

  end;

end;

class function TLVSocket.CheckFound(const pData: Pointer;

  const aKey: variant): boolean;

var

  p:^TSocketStatusInfo;

begin

  p := pData;

  Result := (p.UniqueID = aKey);

end;

constructor TLVSocket.Create;

begin

  inherited Create();

end;

procedure TLVSocket.DeleteLVSocket(

  const aSocketStatus: TSocketStatusInfo; var lvTemp: TListView);

begin

  if SaveSerialStatusToStringList(aSocketStatus) then

  begin

    DeleteDataFromListView(tmpList,lvTemp);

  end;

end;

destructor TLVSocket.Destroy;

begin

  inherited Destroy;

end;

procedure TLVSocket.InitListView(var lvTemp: TListView);

begin

  InitListViewColumns(SocketStrBuffer,SocketWidthBuffer,lvTemp);

end;

class procedure TLVSocket.ProcOnDataDetail(const pData: Pointer;var Item: TListItem);

var

  pSocket:^TSocketStatusInfo;

begin

  //這兩個有什么不同?

  //CopyMemory(pSocket,pData,sizeof(TSocketStatusInfo));

  pSocket := pData;

  Item.Caption := IntToStr(pSocket.GroupID);

  Item.SubItems.Add(IntToStr(pSocket.UniqueID));

  Item.SubItems.Add(pSocket.IPAddress);

  //Item.SubItems.Add(IntToStr(pSocket.CommServerPort));

  Item.SubItems.Add(pSocket.SubItemName);

  Item.SubItems.Add(pSocket.LoginTime);

  Item.SubItems.Add(pSocket.SendNumber);

  Item.SubItems.Add(pSocket.RecNumber);

  Item.SubItems.Add(pSocket.Remark);

  //Item.SubItems.Add(pSocket.IPAddress);

  //Item.SubItems.Add(pSocket.IPAddress);

end;

function TLVSocket.SaveSerialStatusToStringList(

  const aSocketStatus: TSocketStatusInfo): boolean;

begin

  Result := false;

  if Assigned(tmpList) then

  begin

    tmpList.Clear();

    tmpList.Add(IntToStr(aSocketStatus.GroupID));

    tmpList.Add(IntToStr(aSocketStatus.UniqueID));

    tmpList.Add(aSocketStatus.IPAddress);

    tmpList.Add(aSocketStatus.SubItemName);

    tmpList.Add(aSocketStatus.LoginTime);

    tmpList.Add(aSocketStatus.SendNumber);

    tmpList.Add(aSocketStatus.RecNumber);

    tmpList.Add(IntToStr(CSImg_Running));

    Result := true;

  end;

end;

procedure TLVSocket.UpdateLVSocket(

  const aSocketStatus: TSocketStatusInfo; var lvTemp: TListView);

begin

  if SaveSerialStatusToStringList(aSocketStatus) then

  begin

    UpdateDataFromListView(tmpList,lvTemp);

  end;

end;

end.

 

//------------------------------------------------------------------------------

//

//      產品名稱:   成曉旭的個人軟件Delphi源碼庫

//      產品版本:   CXXSoft delphi code source lib 1.0

//      模塊名稱:   Delphi之ListView顯示控制類---外部應用層通用類定義單元

//      模塊描述:   ListView傳統操作方法類

//      單元文件:   unLVCommonClass.pas

//      開發作者:   成曉旭

//      備注:       任何人使用此文件時,請保留此段自述文件,謝謝!

//      開發時間:   2005-09-26

//      修改歷史:   2006-05-31

//      修改描述:   解決GetLVItemOrderByValue()的參數不靈活的問題

//                  並解決Method 'Create' hides virtual method of base type 'TComponent'的問題

//      修改歷史:   2006-06-16

//      修改描述:   增加通過TList來高速增加、更新、刪除數據

//                  先用吧,以后再優化和完善

//      修改歷史:   2006-07-10

//      修改描述:   成功地將ListView的OnData事件的List對象移入此類中,並將其上移到其類

//      修改歷史:   2006-07-11

//      修改描述:   重大重構:將此類分成兩個類:TLVCommonClass-->TLVCommonClass和TLVQuickClass

//                  以遵循SRP原則 

//------------------------------------------------------------------------------

unit unLVCommonClass;

interface

uses

  SysUtils,Classes,ComCtrls,Windows,Variants,

  unLVControler,unLVInterface;

  

const

  SpecialItemOrder = -1;

  CSImg_Normal = 0;

  CSImg_Running = 1;

  GetColumnOrder = 0;

type

  TLVCommonClass = class(TInterfacedObject,ILVControllor)

  private

    cxxLVC:TCXXLVControler;

    class function StrIsNumber(const str:PChar):boolean;

    function  GetLVItemOrderByValue(const lvTemp:TListView;const aKeyValue:string;const columnOrder:integer=SpecialItemOrder):integer;

    procedure CommonListItemProcess(const dataList: TStringList;var liTemp:TListItem; const isUpdate: boolean);

  protected

    //注意:約定最后一項一定是ImageIndex

    tmpList:TStringList;

    function  InitListViewColumns(const displayName: array of string;

        const displayWidth: array of integer;

        var lvTemp:TListView):boolean;

    function  AddDataToListView(const dataList:TStringList;var lvTemp:TListView):boolean;

    function  UpdateDataFromListView(const dataList:TStringList;var lvTemp:TListView):boolean;

    //注意:刪除的鍵值默認以SubItem[0]為標准

    function  DeleteDataFromListView(const dataList:TStringList;var lvTemp:TListView):boolean;

    //子類必須實現

    class function  CheckFound(const pData:Pointer;const aKey:variant):boolean;virtual; abstract;

    class procedure ProcOnDataDetail(const pData:Pointer;var Item: TListItem);virtual; abstract;

    

  public

    constructor Create();overload;

    destructor Destroy();override;

  end;

implementation

...{ TLVCommonClass }

function TLVCommonClass.AddDataToListView(const dataList: TStringList;

  var lvTemp: TListView): boolean;

var

  liTemp:TListItem;

begin

  Result := false;

  if dataList.Count > 0 then

  begin

    lvTemp.Items.BeginUpdate();

    liTemp := lvTemp.Items.Add();

    CommonListItemProcess(dataList,liTemp,false);

    //liTemp.Caption := dataList.Strings[dataIndex];

    //Inc(dataIndex);

    //while (dataIndex < dataList.Count) do

    //begin

    //  liTemp.SubItems.Add(dataList.Strings[dataIndex]);

    //  Inc(dataIndex);

    //end;

    lvTemp.Items.EndUpdate();

    Result := true;

  end;

end;

procedure TLVCommonClass.CommonListItemProcess(const dataList: TStringList;

  var liTemp: TListItem; const isUpdate: boolean);

var

  dataIndex:integer;

begin

  dataIndex := 0;

  liTemp.Caption := dataList.Strings[dataIndex];

  Inc(dataIndex);

  while (dataIndex < dataList.Count) do

  begin

    if (dataIndex = dataList.Count - 1) and StrIsNumber(PChar(dataList.Strings[dataIndex])) then

    begin

      liTemp.ImageIndex := StrToInt(dataList.Strings[dataIndex]); 

    end

    else

    begin

      if isUpdate then

        liTemp.SubItems[dataIndex-1] := dataList.Strings[dataIndex]

      else

        liTemp.SubItems.Add(dataList.Strings[dataIndex]);

    end;

    Inc(dataIndex);

  end;

end;

constructor TLVCommonClass.Create;

begin

  inherited Create();

  cxxLVC := TCXXLVControler.Create();

  tmpList := TStringList.Create();

end;

function TLVCommonClass.DeleteDataFromListView(

  const dataList: TStringList; var lvTemp: TListView): boolean;

var

  colIndex:integer;

//  liTemp:TListItem;

begin

  Result := false;

  if dataList.Count > 0 then

  begin

    colIndex := GetLVItemOrderByValue(lvTemp,dataList.Strings[GetColumnOrder+1],GetColumnOrder);

    if (colIndex <> SpecialItemOrder)  and Assigned(cxxLVC)then

    begin

      cxxLVC.DeleteItemByIndex(lvTemp,colIndex);

      Result := true;

    end;

  end;

end;

destructor TLVCommonClass.Destroy;

begin

  if Assigned(cxxLVC) then

    FreeAndNil(cxxLVC);

  if Assigned(tmpList) then

    FreeAndNil(tmpList);

  inherited Destroy;

end;

function TLVCommonClass.GetLVItemOrderByValue(const lvTemp: TListView;

  const aKeyValue: string; const columnOrder: integer): integer;

var

  Loop:integer;

  isOK:boolean;

begin

  Result := SpecialItemOrder;

  isOK := false;

  for Loop := 0 to lvTemp.Items.Count - 1 do

  begin

    if columnOrder <> SpecialItemOrder then

    begin

      if (columnOrder >= 0) and (columnOrder < lvTemp.Columns.Count) then

        isOK := (lvTemp.Items[Loop].SubItems[columnOrder] = aKeyValue);

    end

    else

      isOK := (lvTemp.Items[Loop].Caption = aKeyValue);

    if isOK then

    begin

      Result := Loop;

      break;

    end;

  end;

end;

function TLVCommonClass.InitListViewColumns(const displayName: array of string;

  const displayWidth: array of integer; var lvTemp: TListView): boolean;

begin

  Result := false;

  if Assigned(cxxLVC) then

  begin

    cxxLVC.InitLVColumns(displayName,displayWidth,lvTemp);

  end;

end;

class function TLVCommonClass.StrIsNumber(const str: PChar): boolean;

var

  p:Char;

  i:integer;

  function CheckHex(p:Char):boolean;

  var

    k:Byte;

  begin

    k := Ord(P);

    Result := ((k >= 48) and (k <= 57)) or ((k >= 65) and (k <= 70)) or ((k >= 97) and (k <= 102));

  end;

begin

  try

    Result := false;

    for i := 0 to Length(str)-1 do

    begin

      p := str[i];

      Result := CheckHex(p);

      if NOT Result then

        break;

    end;

  except

    Result := false;

  end;

end;

function TLVCommonClass.UpdateDataFromListView(

  const dataList: TStringList; var lvTemp: TListView): boolean;

var

  colIndex:integer;

  liTemp:TListItem;

begin

  Result := false;

  if dataList.Count > 0 then

  begin

    colIndex := GetLVItemOrderByValue(lvTemp,dataList.Strings[GetColumnOrder+1],GetColumnOrder);

    if (colIndex <> SpecialItemOrder) then

    begin

      lvTemp.Items.BeginUpdate();

      liTemp := lvTemp.Items[colIndex];

      CommonListItemProcess(dataList,liTemp,true);

      //liTemp.Caption := dataList.Strings[dataIndex];

      //Inc(dataIndex);

      //while (dataIndex < dataList.Count) do

      //begin

      //  liTemp.SubItems[dataIndex-1] := dataList.Strings[dataIndex];

      //  Inc(dataIndex);

      //end;

      lvTemp.Items.EndUpdate();

      Result := true;

    end;

  end;

end;

end.