使用泛型, 寫一個為任意類型的動態數組添加元素的方法

一、使用泛型類:

---

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  end;

  TArr<T> = class
    class procedure ArrayAdd(var Arr: TArray<T>; const item: T);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TArr<T> }

class procedure TArr<T>.ArrayAdd(var Arr: TArray<T>; const item: T);
begin
  SetLength(Arr, Length(Arr)+1);
  Arr[High(Arr)] := item;
end;

//測試
procedure TForm1.FormCreate(Sender: TObject);
var
  arr1: TArray<string>;
  arr2: TArray<Integer>;
begin
  TArr<string>.ArrayAdd(arr1, 'abc');
  TArr<Integer>.ArrayAdd(arr2, 123);
  ShowMessageFmt('%s,%d', [arr1[0], arr2[0]]); //abc,123
end;

end.

---

二、使用泛型結構:

---

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  end;

  TArr<T> = record //record
    class procedure ArrayAdd(var Arr: TArray<T>; const item: T); static; //結構中的 class 方法必須是 static 的
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TArr<T> }

class procedure TArr<T>.ArrayAdd(var Arr: TArray<T>; const item: T);
begin
  SetLength(Arr, Length(Arr)+1);
  Arr[High(Arr)] := item;
end;

//測試
procedure TForm1.FormCreate(Sender: TObject);
var
  arr1: TArray<string>;
  arr2: TArray<Integer>;
begin
  TArr<string>.ArrayAdd(arr1, 'abc');
  TArr<Integer>.ArrayAdd(arr2, 123);
  ShowMessageFmt('%s,%d', [arr1[0], arr2[0]]); //abc,123
end;

end.

---

三、在類或結構中建立泛型方法:

---

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  end;

  TArr = record
    class procedure ArrayAdd<T>(var Arr: TArray<T>; const item: T); static;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TArr }

class procedure TArr.ArrayAdd<T>(var Arr: TArray<T>; const item: T);
begin
  SetLength(Arr, Length(Arr)+1);
  Arr[High(Arr)] := item;
end;

//測試
procedure TForm1.FormCreate(Sender: TObject);
var
  arr1: TArray<string>;
  arr2: TArray<Integer>;
begin
  TArr.ArrayAdd<string>(arr1, 'abc');
  TArr.ArrayAdd<Integer>(arr2, 123);
  ShowMessageFmt('%s,%d', [arr1[0], arr2[0]]); //abc,123
end;

end.

---

四、擴充 System.Generics.Collections 單元中的 TArray 類:

---

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, System.Generics.Collections;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  end;

  Txxx = class helper for TArray
    class procedure ArrayAdd<T>(var Arr: TArray<T>; const item: T); static;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ Txxx }

class procedure Txxx.ArrayAdd<T>(var Arr: TArray<T>; const item: T);
begin
  SetLength(Arr, Length(Arr)+1);
  Arr[High(Arr)] := item;
end;

//測試
procedure TForm1.FormCreate(Sender: TObject);
var
  arr1: TArray<string>;
  arr2: TArray<Integer>;
begin
  TArray.ArrayAdd<string>(arr1, 'abc');
  TArray.ArrayAdd<Integer>(arr2, 123);
  ShowMessageFmt('%s,%d', [arr1[0], arr2[0]]); //abc,123
end;

end.

---

總結:

1、Delphi 的泛型方法只能屬於一個類或結構, 這是好事, 也應該是 Delphi 所提倡的; 這便於管理、也便於快速輸入.

2、稍稍擴充一下就可讓動態數組和其它強大的列表類比拼一下了.

3、這也像是 C++ 中的算法了, 按這個思路應該可以把許多 C++ 中的算法移植過來.

---