【Arduino学习笔记05】Arduino数字输入、输出和脉冲宽带调制 -- 小项目：彩色小台灯

基本功能：

• 长按控制按钮开机，长按控制按钮关机（>3s）
• 通过三个调节按钮调节灯的颜色，每一个按钮分别对应R，G，B值
• 模式切换：短按控制按钮切换模式（长亮模式/闪烁模式）

元器件清单：

• Arduino Uno R3
• 小号面包板
• 跳线
• 10kΩ 电阻（×4）
• 220Ω 电阻（×3）
• USB电缆
• 按键 （×4）
• 5mm 共阴极 RGB LED

知识回顾：（参考书目《Arduino魔法书》）

　　1. 脉冲宽度调制（P25 - P27）

• PWM的输出可以写入数值的范围：0~255
• PWM的工作原理：方波（占空比的概念）
• “你并没有改变输送到LED的电压，为何又能在降低占空比时让LED变暗呢？......如果LED每1ms就开关一次，它看起来就是近乎一半的亮度，这是因为它闪烁的速度超过了人眼能察觉的速度。因此，大脑实际上时平均了这个信号，并欺骗你相信这个LED只有一半的亮度。”

　　2. 上拉电阻和下拉电阻（P28 ~ P30）

• 没有使用下拉电阻的情况

　　

• • 按键没有按下时，要读取的输入引脚什么也没有接——这个输入引脚被称为“悬空”。由于这个引脚没有实际地接到0V或者5V，读取它时会导致意料之外的结果，因为附近的电气噪声会导致其值在高低电平之间来回波动。
• 下拉电阻：将输出端拉一根导线连接到地

　　

　　上拉电阻：将输出端拉一根导线连接到电源

 　　

　　3. 按钮的消抖动（P30 ~ P33）

/*
 * 消抖动函数：
 * button: 要消抖动的按钮
 * last: 该按钮的上一个状态
 * 返回值：消抖动后读回的按钮状态

  * - 这里所谓的消抖动，实际上就是如果检测到电压变化后先不操作，因为可能是抖动阶段的
  * 电压改变，等5m之后再读取当前值，避开抖动阶段。
  * - 如果没有使用消抖动函数，在抖动的过程中电压多次变化，会得到很多次“按钮按下”的
  * 结论，从而造成短时间内频繁的开灯关灯。
*/
boolean debounce(int button, boolean last) {
    boolean current = digitalRead(button);
    if (last != current) {
        delay(5);
        current = digitalRead(button);
    }
    return current;
}

　　4. BlinkWithoutDelay:

　　这里的bilink借鉴的是examples中的BlinkWithoutDelay.ino中的blink方法，这种写法允许在blink的同时做其它工作。比如：读取按钮的输入等。但是如果使用的是Blink.ino中的写法，在delay()的时候是不能做其它工作的。

电路图：

　　

完整源代码：

/* 彩色小台灯

 * 基本功能：   长按控制按钮开机，长按控制按钮关机（>3s）；
                        通过三个调节按钮调节灯的颜色，每一个按钮分别对应R，G，B值；
                        模式切换：短按控制按钮切换模式（长亮模式/闪烁模式）

 * 作者：Shadow
 * 时间 ： 2020/09/08
 */

const int BLED = 9;
const int GLED = 10;
const int RLED = 11;

const int R_BUTTON = 2;
const int G_BUTTON = 3;
const int B_BUTTON = 4;

// 用来记录当前灯颜色对应的RGB值
int R = 0;
int G = 0;
int B = 0;

// lastButton_X是按钮的上一个状态；currentButton_X是按钮的当前状态
// 这里所讲的按钮状态实际上是指按钮所连接的引脚读入的电平值是HIGH还是LOW
// 用来辅助实现按钮消抖函数debounce()
boolean lastButton_R = LOW;
boolean currentButton_R = LOW;
boolean lastButton_G = LOW;
boolean currentButton_G = LOW;
boolean lastButton_B = LOW;
boolean currentButton_B = LOW;

// 辅助实现blink()函数的变量
int ledState = LOW;                      // 记录LED灯的当前状态，LOW: dark; HIGH: light
unsigned long previousMillis = 0;        // will store last time LED was updated
const long interval = 500;               // interval at which to blink (milliseconds)

// 与控制按钮相关的变量
const int MODE_BUTTON = 6;
int mode = 0;                            // 0: 关机; 1: 长亮; 2: blink
boolean lastButton_mode = LOW;
boolean currentButton_mode = LOW;

void setup()
{
    pinMode(BLED, OUTPUT);
    pinMode(GLED, OUTPUT);
    pinMode(RLED, OUTPUT);
    pinMode(R_BUTTON, INPUT);
    pinMode(G_BUTTON, INPUT);
    pinMode(B_BUTTON, INPUT);
    pinMode(MODE_BUTTON, INPUT);
}

/*
 * 消抖动函数：
 * button: 要消抖动的按钮
 * last: 该按钮的上一个状态
 * 返回值：消抖动后读回的按钮状态
*/
boolean debounce(int button, boolean last) {
    boolean current = digitalRead(button);
    if (last != current) {
        delay(5);
        current = digitalRead(button);
    }
    return current;
}

// light the led
void light() {
    analogWrite(RLED, R);
    analogWrite(BLED, B);
    analogWrite(GLED, G);
}

// turn off the led
void dark() {
    digitalWrite(RLED, LOW);
    digitalWrite(BLED, LOW);
    digitalWrite(GLED, LOW);
}

// blink
void blink() {
    // 这里的bilink借鉴的是examples中的BlinkWithoutDelay.ino中的blink方法，这种写法允许在blink的同时做其它工作
    // 比如：读取按钮的输入等。但是如果使用的是Blink.ino中的写法，在delay()的时候是不能做其它工作的。
    unsigned long currentMillis = millis();

    if (currentMillis - previousMillis >= interval) {
        // save the last time you blinked the LED
        previousMillis = currentMillis;

        // if the LED is off turn it on and vice-versa:
        if (ledState == LOW) {
            ledState = HIGH;
            light();
        }
        else {
            ledState = LOW;
            dark();
        }

    }
}

void loop()
{
    // Step1: check the current mode 
    if (mode == 0)
    {
        dark();
    }
    else if (mode == 1) {
        light();
    }
    else {
        blink();
    }
        

    // Step2: change the color if some buttons were pressed
    // read the current state of buttons
    currentButton_R = debounce(R_BUTTON, lastButton_R);
    currentButton_G = debounce(G_BUTTON, lastButton_G);
    currentButton_B = debounce(B_BUTTON, lastButton_B);

    // if button is pressed, change the related rgb value
    if (lastButton_R == LOW && currentButton_R == HIGH) {
        // button_R is pressed
        R += 5;
        if (R == 260)
            R = 0;
    }
    if (lastButton_G == LOW && currentButton_G == HIGH) {
        // button_G is pressed
        G += 5;
        if (G == 260)
            G = 0;
    }
    if (lastButton_B == LOW && currentButton_B == HIGH) {
        // button_B is pressed
        B += 5;
        if (B == 260)
            B = 0;
    }

    // update last state of each button
    lastButton_R = currentButton_R;
    lastButton_G = currentButton_G;
    lastButton_B = currentButton_B;

    //Step3: change the mode if mode_button is pressed, turn on or off if mode_button is pressed more than 3 seconds
    currentButton_mode = debounce(MODE_BUTTON, lastButton_mode);
    if (lastButton_mode == LOW && currentButton_mode == HIGH) {
        // button_mode is pressed, start timing
        unsigned long pressMillis = millis();
        unsigned long releaseMillis = millis();
        while (digitalRead(MODE_BUTTON) == HIGH) {
            releaseMillis = millis();
        }
        // button_mode is released, record the period from press to release
        unsigned long periodMillis = releaseMillis - pressMillis;

        if (periodMillis > 3000 && mode != 0) {
            mode = 0;
        }
        else if (periodMillis > 3000 && mode == 0) {
            // if the previous state is dark, then light
            mode = 1;
        }
        else if (mode == 1) {
            mode = 2;
        }
        else {
            mode = 1;
        }
    }

}

 实验截图：

　　自己设计完成的第一个小项目，留两张照片记录一下吧~