Git自动版本号

@echo off
::------------------------------------------------
:: 作     者：姜  彦 
:: 创建时间 ：2019/10/21 13:31:01
:: WechatQQ ：771078740
:: My Email ：[e-mail] 
::            [e-mail]  
::
:: 描述说明 ：预处理文件
:: 修改历史 ： 
:: 
:: <returns>预处理操作</returns>
::=================================================

::-------------------------------------------------
if "%~1" == "" exit /b 0
setlocal enabledelayedexpansion
REM "$(SolutionDir)Pre-Build.bat" "$(SolutionDir)" "$(SolutionName)" "$(ProjectDir)" "$(ProjectName)" "$(PlatformTarget)" "$(ConfigurationName)" "$(OutDir)" "$(TargetName)" "$(TargetExt)" "$(DefaultLanguageSourceExtension)" "$(TargetDir)"
REM %1 $(SolutionDir)
REM %2 $(SolutionName)
REM %3 $(ProjectDir)
REM %4 $(ProjectName)
REM %5 $(PlatformTarget)
REM %6 $(ConfigurationName)
REM %7 $(OutDir)
REM %8 $(TargetName)
REM %9 $(TargetExt)
REM SHIFT
REM %1 $(DefaultLanguageSourceExtension)
REM %2 $(TargetDir)

set SolutionDir=%~1
set SolutionName=%~2
set ProjectDir=%~3
set ProjectName=%~4
set PlatformTarget=%~5
set ConfigurationName=%~6
set OutDir=%~7
set TargetName=%~8
set TargetExt=%~9
shift & shift & shift & shift & shift & shift & shift & shift & shift
set DefaultLanguageSourceExtension=%~1
set TargetDir=%~2

if 0==1 (
echo SolutionDir=%SolutionDir%
echo SolutionName=%SolutionName%
echo PlatformTarget=%PlatformTarget%
echo ProjectDir=%ProjectDir%
echo ProjectName=%ProjectName%
echo PlatformTarget=%PlatformTarget%
echo ConfigurationName=%ConfigurationName%
echo OutDir=%OutDir%
echo TargetName=%TargetName%
echo TargetExt=%TargetExt%
echo DefaultLanguageSourceExtension=%DefaultLanguageSourceExtension%
echo TargetDir=%TargetDir%
)

SubWCRev.exe >nul 2>nul
if ERRORLEVEL 2 exit /b 0
rem if exist "%TargetDir%zh-CN" (echo ok ) else ( 
rem xcopy /y /e /h %SolutionDir%libs\zh-CN %TargetDir%zh-CN\ >nul
rem )
COPY /y "%ProjectDir%Properties\AssemblyInfo.cs" "%ProjectDir%Properties\AssemblyInfo.cs.bak">NUL
set datevar=%date:~0,4%%date:~5,2%%date:~8,2%
set timevar=%time:~0,2%
if /i %timevar% LSS 10 (
set timevar=0%time:~1,1%
)
set timevar=%timevar%%time:~3,2%%time:~6,2%
set BUILDTIME=%datevar%%timevar%

for /F %%i in ('git rev-parse --short HEAD') do ( set COMMINTID=%%i)
for /F %%i in ('git rev-list HEAD -n 1 ') do ( set SHA=%%i)
for /F %%i in ('git log -1 --format="%%cd" ') do ( set COMMINTTIME=%%i)

SET AssemblyInfo=ASSEMBLY_INFO.tmp
SET FILESTR="%ProjectDir%Properties\AssemblyInfo.cs"
FindStr /v "AssemblyVersion AssemblyFileVersion" %FILESTR%>%AssemblyInfo%
For /f "delims=" %%k In (%SolutionDir%Summary\WPF\WPF\Readme\Git\AssemblyInfo.tpl) do (
  set str=%%k
  set str=!str:GITVERSION=%COMMINTID%,%SHA%,%BUILDTIME%,%COMMINTTIME%!
  echo !str! >> "%AssemblyInfo%"
)

COPY /y "%AssemblyInfo%" "%ProjectDir%Properties\AssemblyInfo.cs"
if "%DefaultLanguageSourceExtension%"==".cpp" goto :CPP
if "%DefaultLanguageSourceExtension%"==".cs" goto :CS

:CPP
if exist "%ProjectDir%Version.rc" (
    if exist "%ProjectDir%Version.rc.bak" (
        if exist "%ProjectDir%SubWCRev.txt" (SubWCRev.exe "%ProjectDir%." "%ProjectDir%SubWCRev.txt" "%ProjectDir%Version.rc" >nul 2>nul || exit /b 0)
    )
)
goto :eof
:CS
if exist "%ProjectDir%Properties\AssemblyInfo.cs" (
    if exist "%ProjectDir%Properties\AssemblyInfo.cs.bak" (
        if exist "%ProjectDir%Properties\SubWCRev.txt" (SubWCRev.exe "%SolutionDir%." "%ProjectDir%Properties\SubWCRev.txt" "%ProjectDir%Properties\AssemblyInfo.cs" >nul 2>nul || exit /b 0)
    )
)

goto :eof

::------------------------------------------------
:: 作     者：姜  彦 
:: 创建时间 ：2019/10/21 13:31:01
:: WechatQQ ：771078740
:: My Email ：[e-mail] 
::            [e-mail]  
::
:: 描述说明 ：预处理文件
:: 修改历史 ： 
:: 
:: <returns>预处理操作</returns>
::=================================================

::-------------------------------------------------
@echo off
if "%~1" == "" exit /b 0

REM "$(SolutionDir)Post-Build.bat" "$(SolutionDir)" "$(SolutionName)" "$(ProjectDir)" "$(ProjectName)" "$(PlatformTarget)" "$(Configuration)" "$(OutDir)" "$(TargetName)" "$(TargetExt)" "$(DefaultLanguageSourceExtension)"
REM %1 $(SolutionDir)
REM %2 $(SolutionName)
REM %3 $(ProjectDir)
REM %4 $(ProjectName)
REM %5 $(PlatformTarget)
REM %6 $(Configuration)
REM %7 $(OutDir)
REM %8 $(TargetName)
REM %9 $(TargetExt)
REM SHIFT
REM %1 $(DefaultLanguageSourceExtension)

set SolutionDir=%~1
set SolutionName=%~2
set ProjectDir=%~3
set ProjectName=%~4
set PlatformTarget=%~5
set Configuration=%~6
set OutDir=%~7
set TargetName=%~8
set TargetExt=%~9
shift & shift & shift & shift & shift & shift & shift & shift & shift
set DefaultLanguageSourceExtension=%~1

if 0==1 (
echo SolutionDir=%SolutionDir%
echo SolutionName=%SolutionName%
echo PlatformTarget=%PlatformTarget%
echo ProjectDir=%ProjectDir%
echo ProjectName=%ProjectName%
echo PlatformTarget=%PlatformTarget%
echo Configuration=%Configuration%
echo OutDir=%OutDir%
echo TargetName=%TargetName%
echo TargetExt=%TargetExt%
echo DefaultLanguageSourceExtension=%DefaultLanguageSourceExtension%
)

if "%DefaultLanguageSourceExtension%"==".cpp" goto :CPP
if "%DefaultLanguageSourceExtension%"==".cs" goto :CS

:CPP
if exist "%ProjectDir%Version.rc" (
    if exist "%ProjectDir%Version.rc.bak" (
        copy "%ProjectDir%Version.rc.bak" "%ProjectDir%Version.rc" /y >nul 2>nul || exit /b 0
    )
)
goto :eof


:CS
if exist "%ProjectDir%Properties\AssemblyInfo.cs" (
    if exist "%ProjectDir%Properties\AssemblyInfo.cs.bak" (
        copy "%ProjectDir%Properties\AssemblyInfo.cs.bak" "%ProjectDir%Properties\AssemblyInfo.cs" /y >nul 2>nul || exit /b 0
        del %ProjectDir%Properties\AssemblyInfo.cs.bak
    )
)
goto :eof

//------------------------------------------------
// 作     者：姜  彦 
// 创建时间 ：2019/10/21 13:31:01
// WechatQQ ：771078740
// My Email ：[e-mail] 
//            [e-mail]  
//
// 描述说明 ：版本号文件
// 修改历史 ： 
// 
// <returns>版本号</returns>
//=================================================

//-------------------------------------------------
[assembly: AssemblyVersion("1.0.0.0")]
[assembly: AssemblyFileVersion("GITVERSION")]